[meta-fsl-arm][PATCH v2 1/7] imx-gpu-viv: Add a new DISTRO check to support XWayland

[meta-fsl-arm][PATCH v2 1/7] imx-gpu-viv: Add a new DISTRO check to support XWayland

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

When X11 and Wayland DISTRO_FEATURES are available, install wayland
related libraries as we will be using X11 on top of Wayland(XWayland).

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc | 35 +++++++++++++---------------
 1 file changed, 16 insertions(+), 19 deletions(-)

diff --git a/recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc b/recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc
index 2c62711..bb366c6 100644
--- a/recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc
+++ b/recipes-graphics/imx-gpu-viv/imx-gpu-viv.inc
@@ -120,25 +120,11 @@ do_install () {
 
     install -d ${D}${libdir}/pkgconfig
 
-    # The preference order, based in DISTRO_FEATURES, is x11, wayland and fb
-    if [ "${USE_X11}" = "yes" ]; then
-        cp -r ${S}/gpu-core/usr/lib/dri ${D}${libdir}
-        cp -r ${S}/apitrace/x11/usr/lib/* ${D}${libdir}
-        cp -r ${S}/apitrace/x11/usr/bin/* ${D}${bindir}
-
-        backend=x11
-
-        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/egl_x11.pc ${D}${libdir}/pkgconfig/egl.pc
-        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv1_cm_x11.pc ${D}${libdir}/pkgconfig/glesv1_cm.pc
-        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv2_x11.pc ${D}${libdir}/pkgconfig/glesv2.pc
-        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/vg_x11.pc ${D}${libdir}/pkgconfig/vg.pc
-        #FIXME: WL & X11 is not currently functional
-        #if [ "${USE_WL}" = "yes" ]; then
-        #    install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/gc_wayland_protocol.pc ${D}${libdir}/pkgconfig/gc_wayland_protocol.pc
-        #    install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/wayland-egl.pc ${D}${libdir}/pkgconfig/wayland-egl.pc
-        #    install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/wayland-viv.pc ${D}${libdir}/pkgconfig/wayland-viv.pc
-        #fi
-    elif [ "${USE_WL}" = "yes" ]; then
+    # The preference order, based in DISTRO_FEATURES, is Wayland (with or without X11), X11 and fb
+    if [ "${USE_WL}" = "yes" ]; then
+        if [ "${USE_X11}" = "yes" ]; then
+            cp -r ${S}/gpu-core/usr/lib/dri ${D}${libdir}
+        fi
         cp -r ${S}/apitrace/non-x11/usr/lib/* ${D}${libdir}
         cp -r ${S}/apitrace/non-x11/usr/bin/* ${D}${bindir}
 
@@ -151,6 +137,17 @@ do_install () {
         install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/gc_wayland_protocol.pc ${D}${libdir}/pkgconfig/gc_wayland_protocol.pc
         install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/wayland-egl.pc ${D}${libdir}/pkgconfig/wayland-egl.pc
         install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/wayland-viv.pc ${D}${libdir}/pkgconfig/wayland-viv.pc
+    elif [ "${USE_X11}" = "yes" ]; then
+        cp -r ${S}/gpu-core/usr/lib/dri ${D}${libdir}
+        cp -r ${S}/apitrace/x11/usr/lib/* ${D}${libdir}
+        cp -r ${S}/apitrace/x11/usr/bin/* ${D}${bindir}
+
+        backend=x11
+
+        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/egl_x11.pc ${D}${libdir}/pkgconfig/egl.pc
+        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv1_cm_x11.pc ${D}${libdir}/pkgconfig/glesv1_cm.pc
+        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv2_x11.pc ${D}${libdir}/pkgconfig/glesv2.pc
+        install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/vg_x11.pc ${D}${libdir}/pkgconfig/vg.pc
     else
         # Regular framebuffer
         install -m 0644 ${S}/gpu-core/usr/lib/pkgconfig/glesv1_cm.pc ${D}${libdir}/pkgconfig/glesv1_cm.pc
-- 
2.1.4

[meta-fsl-arm][PATCH v2 2/7] weston: Add xwayland changes

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

Configure weston to support XWayland backend.

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-graphics/wayland/weston_%.bbappend | 1 +
 1 file changed, 1 insertion(+)

diff --git a/recipes-graphics/wayland/weston_%.bbappend b/recipes-graphics/wayland/weston_%.bbappend
index a7496da..b91370a 100644
--- a/recipes-graphics/wayland/weston_%.bbappend
+++ b/recipes-graphics/wayland/weston_%.bbappend
@@ -11,6 +11,7 @@ EXTRA_OECONF_append_mx6 = " \
     --disable-libunwind \
     --disable-xwayland-test \
     WESTON_NATIVE_BACKEND=fbdev-backend.so \
+   ${@base_contains('DISTRO_FEATURES', 'x11','--enable-xwayland', '--disable-xwayland', d)} \
 "
 EXTRA_OEMAKE_append_mx6 = " \
     COMPOSITOR_CFLAGS="-I ${STAGING_INCDIR}/pixman-1 -DLINUX=1 -DEGL_API_FB -DEGL_API_WL" \
-- 
2.1.4

[meta-fsl-arm][PATCH v2 3/7] weston-init: Add xwayland changes

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

Xwayland needs to be started with virtual terminal so
weston-launch is used.

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-graphics/wayland/weston-init.bbappend      | 13 +++++
 .../wayland/weston-init/weston-launch-init         | 58 ++++++++++++++++++++++
 2 files changed, 71 insertions(+)
 create mode 100644 recipes-graphics/wayland/weston-init.bbappend
 create mode 100644 recipes-graphics/wayland/weston-init/weston-launch-init

diff --git a/recipes-graphics/wayland/weston-init.bbappend b/recipes-graphics/wayland/weston-init.bbappend
new file mode 100644
index 0000000..6473727
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init.bbappend
@@ -0,0 +1,13 @@
+FILESEXTRAPATHS_prepend := "${THISDIR}/${PN}:"
+
+SRC_URI_append_mx6 = " file://weston-launch-init"
+
+USE_WESTON_LAUNCH = "${@base_contains("DISTRO_FEATURES", "x11", "yes", "no", d)}"
+
+do_install_append() {
+
+    if [ "${USE_WESTON_LAUNCH}" = "yes" ]; then
+        install -d ${D}/${sysconfdir}/init.d
+        install -m755 ${WORKDIR}/weston-launch-init ${D}/${sysconfdir}/init.d/weston
+    fi
+}
diff --git a/recipes-graphics/wayland/weston-init/weston-launch-init b/recipes-graphics/wayland/weston-init/weston-launch-init
new file mode 100644
index 0000000..9063c72
--- /dev/null
+++ b/recipes-graphics/wayland/weston-init/weston-launch-init
@@ -0,0 +1,58 @@
+#!/bin/sh
+#
+### BEGIN INIT INFO
+# Provides: weston
+# Required-Start: $local_fs $remote_fs
+# Required-Stop: $local_fs $remote_fs
+# Default-Start:     2 3 4 5
+# Default-Stop:      0 1 6
+### END INIT INFO
+
+killproc() {
+        pid=`/bin/pidof $1`
+        [ "$pid" != "" ] && kill $pid
+}
+
+read CMDLINE < /proc/cmdline
+for x in $CMDLINE; do
+        case $x in
+        weston=false)
+		echo "Weston disabled"
+		exit 0;
+                ;;
+        esac
+done
+
+case "$1" in
+  start)
+        . /etc/profile
+
+        # This is all a nasty hack
+        if test -z "$XDG_RUNTIME_DIR"; then
+                export XDG_RUNTIME_DIR=/run/user/root
+                mkdir --parents $XDG_RUNTIME_DIR
+                chmod 0700 $XDG_RUNTIME_DIR
+        fi
+	mkdir -p /tmp/.X11-unix
+	export XDG_CONFIG_HOME=/etc
+	rm /var/log/weston.log
+	openvt -v -- weston-launch -- --log=/var/log/weston.log
+  ;;
+
+  stop)
+        echo "Stopping Weston"
+        killproc weston
+  ;;
+
+  restart)
+	$0 stop
+        sleep 1
+        $0 start
+  ;;
+
+  *)
+        echo "usage: $0 { start | stop | restart }"
+  ;;
+esac
+
+exit 0
-- 
2.1.4

[meta-fsl-arm][PATCH v2 4/7] glmark2: Use wayland backend whenever it is availiable

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

If Wayland exists in DISTRO features, wayland egl build configuration will be enabled.
It is not mandatory for a GPU driver to support multiple backends (X11, wayland) at the same time.

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend | 5 +++--
 1 file changed, 3 insertions(+), 2 deletions(-)

diff --git a/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend b/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend
index 0e04a65..83f8d15 100644
--- a/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend
+++ b/openembedded-layer/recipes-benchmark/glmark2/glmark2_%.bbappend
@@ -1,3 +1,4 @@
-PACKAGECONFIG_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'x11-gl x11-gles2', \
-                         bb.utils.contains('DISTRO_FEATURES', 'wayland opengl', 'wayland-gles2', '', d), d)}"
+PACKAGECONFIG_mx6  = "${@bb.utils.contains('DISTRO_FEATURES', 'opengl wayland', 'wayland-gles2', \
+                          bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'x11-gl x11-gles2', '', d), d)}"
+
 PACKAGECONFIG_remove_mx6sl = "x11-gles2"
-- 
2.1.4

[meta-fsl-arm][PATCH v2 5/7] mesa-demos: Use wayland backend whenever it is availiable

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

If Wayland exists in DISTRO features, wayland egl build configuration will be enabled
It is not mandatory for a GPU driver to support multiple backends (X11, wayland) at the same time.

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-graphics/mesa/mesa-demos_%.bbappend | 10 +++-------
 1 file changed, 3 insertions(+), 7 deletions(-)

diff --git a/recipes-graphics/mesa/mesa-demos_%.bbappend b/recipes-graphics/mesa/mesa-demos_%.bbappend
index 1f070a4..a8aaf11 100644
--- a/recipes-graphics/mesa/mesa-demos_%.bbappend
+++ b/recipes-graphics/mesa/mesa-demos_%.bbappend
@@ -4,13 +4,9 @@ SRC_URI_append_mx6 = " file://Replace-glWindowPos2iARB-calls-with-glWindowPos2i.
                     file://fix-clear-build-break.patch \
                     file://Additional-eglSwapBuffer-calling-makes-wrong-throttl.patch \
                     file://Add-OpenVG-demos-to-support-wayland.patch"
+PACKAGECONFIG_remove_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', 'x11', '', d)}"
+PACKAGECONFIG_remove_mx6 = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'glu', '', d)}"
 
-PACKAGECONFIG_remove_mx6 = " \
-    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', \
-         bb.utils.contains('DISTRO_FEATURES', 'wayland', 'glu', '', d), d)}"
 PACKAGECONFIG_remove_mx6sl = "gles1 gles2"
 
-PACKAGECONFIG_append = "\
-    ${@bb.utils.contains('DISTRO_FEATURES', 'x11', '', \
-       bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland vg', '', d), d)} \
-"
+PACKAGECONFIG_append_mx6 = " ${@bb.utils.contains('DISTRO_FEATURES', 'wayland', 'wayland vg', '', d)}"
-- 
2.1.4

[meta-fsl-arm][PATCH v2 6/7] chromium: Use Wayland backend whenever it is available

[Tom Hochstein]

From: Neena Busireddy <neena.busireddy@freescale.com>

Do not enable X11 when chromium is running through wayland.
When both X11 and wayland DISTRO_FEATURES are availiable, chromium uses wayland.
Wayland backend is preferred as we are using X11 on top of Wayland (XWayland).

Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 .../recipes-browser/chromium/chromium_40.0.2214.91.bbappend         | 6 ++++++
 1 file changed, 6 insertions(+)

diff --git a/browser-layer/recipes-browser/chromium/chromium_40.0.2214.91.bbappend b/browser-layer/recipes-browser/chromium/chromium_40.0.2214.91.bbappend
index d9c5d15..5d3186e 100644
--- a/browser-layer/recipes-browser/chromium/chromium_40.0.2214.91.bbappend
+++ b/browser-layer/recipes-browser/chromium/chromium_40.0.2214.91.bbappend
@@ -10,3 +10,9 @@ CHROMIUM_IMX_VPU_PATCHES_mx6q += "${VPU_PATCHES}"
 CHROMIUM_IMX_VPU_PATCHES_mx6dl += "${VPU_PATCHES}"
 
 CHROMIUM_IMX_WAYLAND_PATCHES += "file://${PATCH_BASE_DIR}/wayland/0001-Modify-eglwayland-versions-for-Vivante-GPUs.patch"
+
+# Don't use X if it's running through Wayland
+ENABLE_X11 = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '0', \
+                 bb.utils.contains('DISTRO_FEATURES', 'x11', '1', \
+                 '0', d), d)}"
+ENABLE_WAYLAND = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '1', '0', d)}"
-- 
2.1.4

[meta-fsl-arm][PATCH v2 7/7] gstreamer: Add XWayland change

[Tom Hochstein]

Configure gstreamer build for XWayland backend.

Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>
---
 recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb | 3 ++-
 1 file changed, 2 insertions(+), 1 deletion(-)

diff --git a/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb b/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb
index 62b38c7..6ee04c7 100644
--- a/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb
+++ b/recipes-multimedia/gstreamer/gst1.0-fsl-plugin_4.0.7.bb
@@ -41,7 +41,8 @@ PLATFORM_mx7= "MX7D"
 # Todo add a mechanism to map possible build targets
 EXTRA_OECONF = "PLATFORM=${PLATFORM} \
                 CPPFLAGS="-I${STAGING_KERNEL_DIR}/include/uapi -I${STAGING_KERNEL_DIR}/include" \
-                CROSS_ROOT=${PKG_CONFIG_SYSROOT_DIR}"
+                CROSS_ROOT=${PKG_CONFIG_SYSROOT_DIR} \
+                ${@bb.utils.contains('DISTRO_FEATURES', 'x11 wayland', '--disable-x11', '', d)}"
 
 PACKAGES =+ "${PN}-gplay ${PN}-libgplaycore ${PN}-libgstfsl ${PN}-grecorder ${PN}-librecorder-engine"
 
-- 
2.1.4

Re: [meta-fsl-arm][PATCH v2 2/7] weston: Add xwayland changes

[Otavio Salvador]

On Mon, Nov 16, 2015 at 4:00 PM, Tom Hochstein
<tom.hochstein@freescale.com> wrote:
> From: Neena Busireddy <neena.busireddy@freescale.com>
>
> Configure weston to support XWayland backend.
>
> Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
> Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>

OE-Core provides a PACKAGECONFIG for it now, use it.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [meta-fsl-arm][PATCH v2 3/7] weston-init: Add xwayland changes

[Otavio Salvador]

On Mon, Nov 16, 2015 at 4:00 PM, Tom Hochstein
<tom.hochstein@freescale.com> wrote:
> From: Neena Busireddy <neena.busireddy@freescale.com>
>
> Xwayland needs to be started with virtual terminal so
> weston-launch is used.
>
> Signed-off-by: Neena Busireddy <neena.busireddy@freescale.com>
> Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>

Why we cannot integrate this onto the weston init? We need to handle
this in OE-Core as it has no BSP specific bits here.

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750

Re: [meta-fsl-arm][PATCH v2 7/7] gstreamer: Add XWayland change

[Otavio Salvador]

On Mon, Nov 16, 2015 at 4:00 PM, Tom Hochstein
<tom.hochstein@freescale.com> wrote:
> Configure gstreamer build for XWayland backend.
>
> Signed-off-by: Tom Hochstein <tom.hochstein@freescale.com>

Move this to a PACKAGECONFIG setting

-- 
Otavio Salvador                             O.S. Systems
http://www.ossystems.com.br        http://code.ossystems.com.br
Mobile: +55 (53) 9981-7854            Mobile: +1 (347) 903-9750