All of lore.kernel.org
 help / color / mirror / Atom feed
* [PATCH 0/3] ltp: Add recipe from OE
@ 2011-12-02 15:48 Jiajun Xu
  2011-12-02 15:54 ` [PATCH 1/3] " Jiajun Xu
                   ` (2 more replies)
  0 siblings, 3 replies; 7+ messages in thread
From: Jiajun Xu @ 2011-12-02 15:48 UTC (permalink / raw)
  To: openembedded-core

The pull request is to address [YOCTO #1568] - "Add recipe for ltp/posix tests and automate test".
ltp is ported from OE and updated to latest version(20110915). Testcases are installed 
to ${D}/opt/ltp and POISX test suite is also copied into ${D}/opt/ltp/testcases folder. 
Include ltp to testapps list.

Note that some cases are removed from ltp since they depend on expect. Currently
there is no expect recipe in OE and we will add it for enhancement next.

The following changes since commit e57935dc18d576feb1003b48e7cdc72a444131b8:

  Revert "classes/buildhistory: add new output history collection class" (2011-12-01 23:00:52 +0000)

are available in the git repository at:
  git://git.pokylinux.org/poky-contrib jxu49/oe-contrib
  http://git.pokylinux.org/cgit.cgi/poky-contrib/log/?h=jxu49/oe-contrib

Jiajun Xu (3):
  ltp: Add recipe from OE
  distro_tracking_fields: add information for ltp
  task-core-tools: add ltp to testapps list

 .../conf/distro/include/distro_tracking_fields.inc |    8 +++
 meta/recipes-core/tasks/task-core-tools.bb         |    3 +-
 meta/recipes-extended/ltp/ltp_20110915.bb          |   67 ++++++++++++++++++++
 3 files changed, 77 insertions(+), 1 deletions(-)
 create mode 100644 meta/recipes-extended/ltp/ltp_20110915.bb




^ permalink raw reply	[flat|nested] 7+ messages in thread
* [PATCH 1/3] ltp: Add recipe from OE
  2011-12-02 15:48 [PATCH 0/3] ltp: Add recipe from OE Jiajun Xu
@ 2011-12-02 15:54 ` Jiajun Xu
  2011-12-03 23:39   ` Saul Wold
  2011-12-02 15:54 ` [PATCH 2/3] distro_tracking_fields: add information for ltp Jiajun Xu
  2011-12-02 15:54 ` [PATCH 3/3] task-core-tools: add ltp to testapps list Jiajun Xu
  2 siblings, 1 reply; 7+ messages in thread
From: Jiajun Xu @ 2011-12-02 15:54 UTC (permalink / raw)
  To: openembedded-core

Port ltp recipe from OE and upgraged to latest version(20110915).
Install ltp into ${D}/opt/ltp and POSIX test suite is also copied
into ${D}/opt/ltp/testcases.

TODO: Some cases are removed since they depend on command 'expect'.
It is not in Poky or OE and we will add it for enhancement next.

Signed-off-by: Jiajun Xu <jiajun.xu@intel.com>
---
 meta/recipes-extended/ltp/ltp_20110915.bb |   67 +++++++++++++++++++++++++++++
 1 files changed, 67 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-extended/ltp/ltp_20110915.bb

diff --git a/meta/recipes-extended/ltp/ltp_20110915.bb b/meta/recipes-extended/ltp/ltp_20110915.bb
new file mode 100644
index 0000000..ff5ea47
--- /dev/null
+++ b/meta/recipes-extended/ltp/ltp_20110915.bb
@@ -0,0 +1,67 @@
+SUMMARY = "Linux Test Project"
+DESCRIPTION = "The Linux Test Project is a joint project with SGI, IBM, OSDL, and Bull with a goal to deliver test suites to the open source community that validate the reliability, robustness, and stability of Linux. The Linux Test Project is a collection of tools for testing the Linux kernel and related features."
+HOMEPAGE = "http://ltp.sourceforge.net"
+SECTION = "console/utils"
+
+PR = "r0"
+
+LICENSE = "GPLv2 & GPLv2+ & LGPLv2+ & LGPLv2.1+ & BSD-2-Clause"
+SRC_URI = "${SOURCEFORGE_MIRROR}/ltp/ltp-full-${PV}.bz2"
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+		    file://testcases/kernel/mce-test/COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+		    file://testcases/kernel/controllers/freezer/COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+		    file://testcases/kernel/controllers/freezer/run_freezer.sh;startline=5;endline=17;md5=aeac3f7691caa2e76fd5a732fbd6510d \
+		    file://testcases/kernel/fs/ext4-new-features/ffsb-6.0-rc2/COPYING;md5=c46082167a314d785d012a244748d803 \
+		    file://testcases/kernel/hotplug/memory_hotplug/COPYING;md5=e04a2e542b2b8629bf9cd2ba29b0fe41 \
+		    file://testcases/kernel/hotplug/cpu_hotplug/COPYING;md5=e04a2e542b2b8629bf9cd2ba29b0fe41 \
+		    file://testcases/open_posix_testsuite/COPYING;md5=216e43b72efbe4ed9017cc19c4c68b01 \
+		    file://tools/netpipe-2.4/COPYING;md5=18810669f13b87348459e611d31ab760 \
+		    file://tools/netpipe-2.4-ipv6/COPYING;md5=18810669f13b87348459e611d31ab760 \
+		    file://tools/top-LTP/proc/COPYING;md5=6e29c688d912da12b66b73e32b03d812 \
+		    file://tools/pounder21/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+		    file://utils/benchmark/kernbench-0.42/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+		"
+
+SRC_URI[md5sum] = "582fb78d7bf78a624a4387f29327d166"
+SRC_URI[sha256sum] = "013f7f2f6fdf46b7d73216533c3d4c2d91f0a2cec522bf026f7c8920ede83d2c"
+
+export prefix = "/opt/ltp"
+export exec_prefix = "/opt/ltp"
+
+inherit autotools
+
+FILES_${PN}-dbg += "/opt/ltp/runtest/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testcases/bin/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testcases/bin/*/bin/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testcases/bin/*/test/.debug"
+FILES_${PN}-dbg += "/opt/ltp/scenario_groups/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testscripts/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testscripts/open_posix_testsuite/.debug"
+
+FILES_${PN} += "/opt/ltp/* /opt/ltp/runtest/* /opt/ltp/scenario_groups/* /opt/ltp/testcases/bin/* /opt/ltp/testcases/bin/*/bin/* /opt/ltp/testscripts/* /opt/ltp/testcases/open_posix_testsuite/* /opt/ltp/testcases/open_posix_testsuite/conformance/* /opt/ltp/testcases/open_posix_testsuite/Documentation/* /opt/ltp/testcases/open_posix_testsuite/functional/* /opt/ltp/testcases/open_posix_testsuite/include/* /opt/ltp/testcases/open_posix_testsuite/scripts/* /opt/ltp/testcases/open_posix_testsuite/stress/* /opt/ltp/testcases/open_posix_testsuite/tools/*"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+do_unpack_append() {
+        bb.build.exec_func('do_extract_tarball', d)
+}
+
+do_extract_tarball() {
+	if test -f ${WORKDIR}/ltp-full-${PV} ; then
+	    tar x --no-same-owner -f ${WORKDIR}/ltp-full-${PV}
+	    mv ${WORKDIR}/ltp-full-${PV} ${WORKDIR}/ltp-${PV}
+	fi
+}
+
+do_install(){
+	install -d ${D}/opt/ltp/
+	oe_runmake DESTDIR=${D} SKIP_IDCHECK=1 install
+	
+	# Copy POSIX test suite into ${D}/opt/ltp/testcases by manual
+	cp -r testcases/open_posix_testsuite ${D}/opt/ltp/testcases
+
+	# We need to remove all scripts which depend on /usr/bin/expect, since expect is not supported in poky
+	# We will add expect for enhancement in future
+	find ${D} -type f -print | xargs grep "\!.*\/usr\/bin\/expect" | awk -F":" '{print $1}' | xargs rm -f
+}
-- 
1.7.1




^ permalink raw reply related	[flat|nested] 7+ messages in thread
* [PATCH 2/3] distro_tracking_fields: add information for ltp
  2011-12-02 15:48 [PATCH 0/3] ltp: Add recipe from OE Jiajun Xu
  2011-12-02 15:54 ` [PATCH 1/3] " Jiajun Xu
@ 2011-12-02 15:54 ` Jiajun Xu
  2011-12-02 15:54 ` [PATCH 3/3] task-core-tools: add ltp to testapps list Jiajun Xu
  2 siblings, 0 replies; 7+ messages in thread
From: Jiajun Xu @ 2011-12-02 15:54 UTC (permalink / raw)
  To: openembedded-core

Add information for recipe ltp, which is ported from OE.

Signed-off-by: Jiajun Xu <jiajun.xu@intel.com>
---
 .../conf/distro/include/distro_tracking_fields.inc |    8 ++++++++
 1 files changed, 8 insertions(+), 0 deletions(-)

diff --git a/meta/conf/distro/include/distro_tracking_fields.inc b/meta/conf/distro/include/distro_tracking_fields.inc
index 073521f..fa15f24 100644
--- a/meta/conf/distro/include/distro_tracking_fields.inc
+++ b/meta/conf/distro/include/distro_tracking_fields.inc
@@ -6092,6 +6092,14 @@ RECIPE_MANUAL_CHECK_DATE_pn-libiconv = "Nov 22, 2011"
 DISTRO_PN_ALIAS_pn-libiconv = "Fedora=mingw-libiconv Opensuse=cross-mingw-libiconv"
 RECIPE_MAINTAINER_pn-libiconv = "Saul Wold <sgw@linux.intel.com>"
 
+RECIPE_STATUS_pn-ltp = "green"
+RECIPE_LATEST_VERSION_pn-ltp = "20110915"
+RECIPE_LATEST_RELEASE_DATE_pn-ltp = "Sep 15, 2011"
+RECIPE_TIME_BETWEEN_LAST_TWO_RELEASES_pn-ltp = "3 months"
+RECIPE_NO_OF_PATCHES_pn-ltp = "0"
+RECIPE_LAST_UPDATE_pn-ltp = "Dec 2, 2011"
+RECIPE_MAINTAINER_pn-ltp = "Jiajun Xu <jiajun.xu@intel.com>"
+
 DISTRO_PN_ALIAS_pn-qt4-native = "Fedora=qt4 Debian=qt4-dev-tools"
 DISTRO_PN_ALIAS_pn-update-alternatives-dpkg = "Opensuse=update-alternatives Mandriva=update-alternatives"
 RECIPE_MAINTAINER_pn-update-alternatives-dpkg = "Dongxiao Xu <dongxiao.xu@intel.com>"
-- 
1.7.1




^ permalink raw reply related	[flat|nested] 7+ messages in thread
* [PATCH 3/3] task-core-tools: add ltp to testapps list
  2011-12-02 15:48 [PATCH 0/3] ltp: Add recipe from OE Jiajun Xu
  2011-12-02 15:54 ` [PATCH 1/3] " Jiajun Xu
  2011-12-02 15:54 ` [PATCH 2/3] distro_tracking_fields: add information for ltp Jiajun Xu
@ 2011-12-02 15:54 ` Jiajun Xu
  2 siblings, 0 replies; 7+ messages in thread
From: Jiajun Xu @ 2011-12-02 15:54 UTC (permalink / raw)
  To: openembedded-core

Signed-off-by: Jiajun Xu <jiajun.xu@intel.com>
---
 meta/recipes-core/tasks/task-core-tools.bb |    3 ++-
 1 files changed, 2 insertions(+), 1 deletions(-)

diff --git a/meta/recipes-core/tasks/task-core-tools.bb b/meta/recipes-core/tasks/task-core-tools.bb
index 12d4ff9..6632b4f 100644
--- a/meta/recipes-core/tasks/task-core-tools.bb
+++ b/meta/recipes-core/tasks/task-core-tools.bb
@@ -6,7 +6,7 @@ DESCRIPTION = "Tools tasks for OE-Core"
 LICENSE = "MIT"
 LIC_FILES_CHKSUM = "file://${COREBASE}/LICENSE;md5=3f40d7994397109285ec7b81fdeb3b58 \
                     file://${COREBASE}/meta/COPYING.MIT;md5=3da9cfbcb788c80a0384361b4de20420"
-PR = "r13"
+PR = "r14"
 
 PACKAGES = "\
     task-core-tools-debug \
@@ -98,4 +98,5 @@ RDEPENDS_task-core-tools-testapps = "\
     xprop \
     xvideo-tests \
     clutter-box2d \
+    ltp \
     "
-- 
1.7.1




^ permalink raw reply related	[flat|nested] 7+ messages in thread
* Re: [PATCH 1/3] ltp: Add recipe from OE
  2011-12-02 15:54 ` [PATCH 1/3] " Jiajun Xu
@ 2011-12-03 23:39   ` Saul Wold
  2011-12-21 15:49     ` Xu, Jiajun
  0 siblings, 1 reply; 7+ messages in thread
From: Saul Wold @ 2011-12-03 23:39 UTC (permalink / raw)
  To: Patches and discussions about the oe-core layer

On 12/02/2011 07:54 AM, Jiajun Xu wrote:
> Port ltp recipe from OE and upgraged to latest version(20110915).
> Install ltp into ${D}/opt/ltp and POSIX test suite is also copied
> into ${D}/opt/ltp/testcases.
>
> TODO: Some cases are removed since they depend on command 'expect'.
> It is not in Poky or OE and we will add it for enhancement next.
>
> Signed-off-by: Jiajun Xu<jiajun.xu@intel.com>
> ---
>   meta/recipes-extended/ltp/ltp_20110915.bb |   67 +++++++++++++++++++++++++++++
>   1 files changed, 67 insertions(+), 0 deletions(-)
>   create mode 100644 meta/recipes-extended/ltp/ltp_20110915.bb
>
> diff --git a/meta/recipes-extended/ltp/ltp_20110915.bb b/meta/recipes-extended/ltp/ltp_20110915.bb
> new file mode 100644
> index 0000000..ff5ea47
> --- /dev/null
> +++ b/meta/recipes-extended/ltp/ltp_20110915.bb
> @@ -0,0 +1,67 @@
> +SUMMARY = "Linux Test Project"
> +DESCRIPTION = "The Linux Test Project is a joint project with SGI, IBM, OSDL, and Bull with a goal to deliver test suites to the open source community that validate the reliability, robustness, and stability of Linux. The Linux Test Project is a collection of tools for testing the Linux kernel and related features."
> +HOMEPAGE = "http://ltp.sourceforge.net"
> +SECTION = "console/utils"
> +
> +PR = "r0"
> +
> +LICENSE = "GPLv2&  GPLv2+&  LGPLv2+&  LGPLv2.1+&  BSD-2-Clause"
> +SRC_URI = "${SOURCEFORGE_MIRROR}/ltp/ltp-full-${PV}.bz2"
> +

SRC_URI should go below the LIC_FILES_CHKSUM.

> +LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
> +		    file://testcases/kernel/mce-test/COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
> +		    file://testcases/kernel/controllers/freezer/COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
> +		    file://testcases/kernel/controllers/freezer/run_freezer.sh;startline=5;endline=17;md5=aeac3f7691caa2e76fd5a732fbd6510d \
> +		    file://testcases/kernel/fs/ext4-new-features/ffsb-6.0-rc2/COPYING;md5=c46082167a314d785d012a244748d803 \
> +		    file://testcases/kernel/hotplug/memory_hotplug/COPYING;md5=e04a2e542b2b8629bf9cd2ba29b0fe41 \
> +		    file://testcases/kernel/hotplug/cpu_hotplug/COPYING;md5=e04a2e542b2b8629bf9cd2ba29b0fe41 \
> +		    file://testcases/open_posix_testsuite/COPYING;md5=216e43b72efbe4ed9017cc19c4c68b01 \
> +		    file://tools/netpipe-2.4/COPYING;md5=18810669f13b87348459e611d31ab760 \
> +		    file://tools/netpipe-2.4-ipv6/COPYING;md5=18810669f13b87348459e611d31ab760 \
> +		    file://tools/top-LTP/proc/COPYING;md5=6e29c688d912da12b66b73e32b03d812 \
> +		    file://tools/pounder21/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
> +		    file://utils/benchmark/kernbench-0.42/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
> +		"
> +
> +SRC_URI[md5sum] = "582fb78d7bf78a624a4387f29327d166"
> +SRC_URI[sha256sum] = "013f7f2f6fdf46b7d73216533c3d4c2d91f0a2cec522bf026f7c8920ede83d2c"
> +
> +export prefix = "/opt/ltp"
> +export exec_prefix = "/opt/ltp"
> +
> +inherit autotools
> +
> +FILES_${PN}-dbg += "/opt/ltp/runtest/.debug"
> +FILES_${PN}-dbg += "/opt/ltp/testcases/bin/.debug"
> +FILES_${PN}-dbg += "/opt/ltp/testcases/bin/*/bin/.debug"
> +FILES_${PN}-dbg += "/opt/ltp/testcases/bin/*/test/.debug"
> +FILES_${PN}-dbg += "/opt/ltp/scenario_groups/.debug"
> +FILES_${PN}-dbg += "/opt/ltp/testscripts/.debug"
> +FILES_${PN}-dbg += "/opt/ltp/testscripts/open_posix_testsuite/.debug"
> +
> +FILES_${PN} += "/opt/ltp/* /opt/ltp/runtest/* /opt/ltp/scenario_groups/* /opt/ltp/testcases/bin/* /opt/ltp/testcases/bin/*/bin/* /opt/ltp/testscripts/* /opt/ltp/testcases/open_posix_testsuite/* /opt/ltp/testcases/open_posix_testsuite/conformance/* /opt/ltp/testcases/open_posix_testsuite/Documentation/* /opt/ltp/testcases/open_posix_testsuite/functional/* /opt/ltp/testcases/open_posix_testsuite/include/* /opt/ltp/testcases/open_posix_testsuite/scripts/* /opt/ltp/testcases/open_posix_testsuite/stress/* /opt/ltp/testcases/open_posix_testsuite/tools/*"
> +
> +TARGET_CC_ARCH += "${LDFLAGS}"
> +
> +do_unpack_append() {
> +        bb.build.exec_func('do_extract_tarball', d)
> +}
> +
> +do_extract_tarball() {
> +	if test -f ${WORKDIR}/ltp-full-${PV} ; then
> +	    tar x --no-same-owner -f ${WORKDIR}/ltp-full-${PV}
> +	    mv ${WORKDIR}/ltp-full-${PV} ${WORKDIR}/ltp-${PV}
> +	fi
> +}
> +
The "mv" seems to cause a problem.  Is there a reason you do this 
instead of just setting "S = ${WORKDIR}/ltp-full-${PV} if that's what 
the tarball normally extracts to?



ERROR: Function 'do_extract_tarball' failed (see 
/srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/tmp/work/i586-poky-linux/ltp-20110915-r0/temp/log.do_unpack.714 
for further information)
ERROR: Logfile of failure stored in: 
/srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/tmp/work/i586-poky-linux/ltp-20110915-r0/temp/log.do_unpack.714
Log data follows:
| NOTE: Unpacking /srv/home/swold/downloads/ltp-full-20110915.bz2 to 
/srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/tmp/work/i586-poky-linux/ltp-20110915-r0/
| DEBUG: SITE files ['endian-little', 'bit-32', 'ix86-common', 
'common-linux', 'common-glibc', 'i586-linux', 'common']
| ERROR: Function 'do_extract_tarball' failed (see 
/srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/tmp/work/i586-poky-linux/ltp-20110915-r0/temp/log.do_unpack.714 
for further information)
| mv: cannot overwrite directory 
`/srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/tmp/work/i586-poky-linux/ltp-20110915-r0/ltp-20110915/ltp-full-20110915' 
with non-directory
NOTE: package ltp-20110915-r0: task do_unpack: Failed
ERROR: Task 2303 
(/srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/meta/recipes-extended/ltp/ltp_20110915.bb, 
do_unpack) failed with exit code '1'

> +do_install(){
> +	install -d ${D}/opt/ltp/
> +	oe_runmake DESTDIR=${D} SKIP_IDCHECK=1 install
> +	
> +	# Copy POSIX test suite into ${D}/opt/ltp/testcases by manual
> +	cp -r testcases/open_posix_testsuite ${D}/opt/ltp/testcases
> +
> +	# We need to remove all scripts which depend on /usr/bin/expect, since expect is not supported in poky
> +	# We will add expect for enhancement in future
> +	find ${D} -type f -print | xargs grep "\!.*\/usr\/bin\/expect" | awk -F":" '{print $1}' | xargs rm -f
> +}



^ permalink raw reply	[flat|nested] 7+ messages in thread
* Re: [PATCH 1/3] ltp: Add recipe from OE
  2011-12-03 23:39   ` Saul Wold
@ 2011-12-21 15:49     ` Xu, Jiajun
  0 siblings, 0 replies; 7+ messages in thread
From: Xu, Jiajun @ 2011-12-21 15:49 UTC (permalink / raw)
  To: Saul Wold, Patches and discussions about the oe-core layer


> The "mv" seems to cause a problem.  Is there a reason you do this
> instead of just setting "S = ${WORKDIR}/ltp-full-${PV} if that's what
> the tarball normally extracts to?
> 

Sorry for late response, Saul. If I set S to ltp-full-${PV}, do_unpack will report that ltp-full-${PV} is not a directory. It is due to that the source file for ltp is named as "ltp-full-${PV}.bz2", which in fact should be extracted by bzip2 and tar. But the unpack code in bitbake could not handle this so I have to add some extra code for it.
I have modified the patch to make the unpack pass and will send out again for review.

Thanks a lot.

> 
> 
> ERROR: Function 'do_extract_tarball' failed (see
> /srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/
> tmp/w ork/i586-poky-linux/ltp-20110915-r0/temp/log.do_unpack.714 for
> further information) ERROR: Logfile of failure stored in:
> /srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/
> tmp/w ork/i586-poky-linux/ltp-20110915-r0/temp/log.do_unpack.714 Log
> data follows: | NOTE: Unpacking
> /srv/home/swold/downloads/ltp-full-20110915.bz2 to
> /srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/
> tmp/w ork/i586-poky-linux/ltp-20110915-r0/ | DEBUG: SITE files
> ['endian-little', 'bit-32', 'ix86-common', 'common-linux',
> 'common-glibc', 'i586-linux', 'common'] | ERROR: Function
> 'do_extract_tarball' failed (see
> /srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build/
> tmp/w ork/i586-poky-linux/ltp-20110915-r0/temp/log.do_unpack.714 for
> further information) | mv: cannot overwrite directory
> `/srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/build
> /tmp/w
> ork/i586-poky-linux/ltp-20110915-r0/ltp-20110915/ltp-full-20110915' with
> non-directory NOTE: package ltp-20110915-r0: task do_unpack: Failed
> ERROR: Task 2303
> (/srv/home/swold/yocto-autobuilder/yocto-slave/nightly-x86/build/meta/
> recipe s-extended/ltp/ltp_20110915.bb, do_unpack) failed with exit code
> '1'
> 
>> +do_install(){ +	install -d ${D}/opt/ltp/ +	oe_runmake DESTDIR=${D}
>> SKIP_IDCHECK=1 install + +	# Copy POSIX test suite into
>> ${D}/opt/ltp/testcases by manual +	cp -r testcases/open_posix_testsuite
>> ${D}/opt/ltp/testcases + +	# We need to remove all scripts which depend
>> on /usr/bin/expect, +since expect is not supported in poky +	# We will
>> add expect for enhancement in future +	find ${D} -type f -print | xargs
>> grep "\!.*\/usr\/bin\/expect" | +awk -F":" '{print $1}' | xargs rm -f }

Best Regards,
Jiajun





^ permalink raw reply	[flat|nested] 7+ messages in thread
* [PATCH 1/3] ltp: Add recipe from OE
  2011-12-21 16:45 [PATCH 0/3] ltp: Add recipe from OE Jiajun Xu
@ 2011-12-21 16:45 ` Jiajun Xu
  0 siblings, 0 replies; 7+ messages in thread
From: Jiajun Xu @ 2011-12-21 16:45 UTC (permalink / raw)
  To: openembedded-core

Port ltp recipe from OE and upgraged to latest version(20110915).
Install ltp into ${D}/opt/ltp and POSIX test suite is also copied
into ${D}/opt/ltp/testcases.

TODO: Some cases are removed since they depend on command 'expect'.
It is not in Poky or OE and we will add it for enhancement next.

Signed-off-by: Jiajun Xu <jiajun.xu@intel.com>
---
 meta/recipes-extended/ltp/ltp_20110915.bb |   68 +++++++++++++++++++++++++++++
 1 files changed, 68 insertions(+), 0 deletions(-)
 create mode 100644 meta/recipes-extended/ltp/ltp_20110915.bb

diff --git a/meta/recipes-extended/ltp/ltp_20110915.bb b/meta/recipes-extended/ltp/ltp_20110915.bb
new file mode 100644
index 0000000..dabc0f0
--- /dev/null
+++ b/meta/recipes-extended/ltp/ltp_20110915.bb
@@ -0,0 +1,68 @@
+SUMMARY = "Linux Test Project"
+DESCRIPTION = "The Linux Test Project is a joint project with SGI, IBM, OSDL, and Bull with a goal to deliver test suites to the open source community that validate the reliability, robustness, and stability of Linux. The Linux Test Project is a collection of tools for testing the Linux kernel and related features."
+HOMEPAGE = "http://ltp.sourceforge.net"
+SECTION = "console/utils"
+
+PR = "r0"
+
+LICENSE = "GPLv2 & GPLv2+ & LGPLv2+ & LGPLv2.1+ & BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+		    file://testcases/kernel/mce-test/COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+		    file://testcases/kernel/controllers/freezer/COPYING;md5=0636e73ff0215e8d672dc4c32c317bb3 \
+		    file://testcases/kernel/controllers/freezer/run_freezer.sh;startline=5;endline=17;md5=aeac3f7691caa2e76fd5a732fbd6510d \
+		    file://testcases/kernel/fs/ext4-new-features/ffsb-6.0-rc2/COPYING;md5=c46082167a314d785d012a244748d803 \
+		    file://testcases/kernel/hotplug/memory_hotplug/COPYING;md5=e04a2e542b2b8629bf9cd2ba29b0fe41 \
+		    file://testcases/kernel/hotplug/cpu_hotplug/COPYING;md5=e04a2e542b2b8629bf9cd2ba29b0fe41 \
+		    file://testcases/open_posix_testsuite/COPYING;md5=216e43b72efbe4ed9017cc19c4c68b01 \
+		    file://tools/netpipe-2.4/COPYING;md5=18810669f13b87348459e611d31ab760 \
+		    file://tools/netpipe-2.4-ipv6/COPYING;md5=18810669f13b87348459e611d31ab760 \
+		    file://tools/top-LTP/proc/COPYING;md5=6e29c688d912da12b66b73e32b03d812 \
+		    file://tools/pounder21/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+		    file://utils/benchmark/kernbench-0.42/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
+		"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/ltp/ltp-full-${PV}.bz2"
+
+SRC_URI[md5sum] = "582fb78d7bf78a624a4387f29327d166"
+SRC_URI[sha256sum] = "013f7f2f6fdf46b7d73216533c3d4c2d91f0a2cec522bf026f7c8920ede83d2c"
+
+export prefix = "/opt/ltp"
+export exec_prefix = "/opt/ltp"
+
+inherit autotools
+
+FILES_${PN}-dbg += "/opt/ltp/runtest/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testcases/bin/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testcases/bin/*/bin/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testcases/bin/*/test/.debug"
+FILES_${PN}-dbg += "/opt/ltp/scenario_groups/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testscripts/.debug"
+FILES_${PN}-dbg += "/opt/ltp/testscripts/open_posix_testsuite/.debug"
+
+FILES_${PN} += "/opt/ltp/* /opt/ltp/runtest/* /opt/ltp/scenario_groups/* /opt/ltp/testcases/bin/* /opt/ltp/testcases/bin/*/bin/* /opt/ltp/testscripts/* /opt/ltp/testcases/open_posix_testsuite/* /opt/ltp/testcases/open_posix_testsuite/conformance/* /opt/ltp/testcases/open_posix_testsuite/Documentation/* /opt/ltp/testcases/open_posix_testsuite/functional/* /opt/ltp/testcases/open_posix_testsuite/include/* /opt/ltp/testcases/open_posix_testsuite/scripts/* /opt/ltp/testcases/open_posix_testsuite/stress/* /opt/ltp/testcases/open_posix_testsuite/tools/*"
+
+TARGET_CC_ARCH += "${LDFLAGS}"
+
+do_unpack_append() {
+        bb.build.exec_func('do_extract_tarball', d)
+}
+
+do_extract_tarball() {
+	if test -f ${WORKDIR}/ltp-full-${PV} ; then
+	    tar x --no-same-owner -f ${WORKDIR}/ltp-full-${PV} -C ${WORKDIR}
+	    rm -rf ${WORKDIR}/ltp-${PV}
+	    mv ${WORKDIR}/ltp-full-${PV} ${WORKDIR}/ltp-${PV}
+	fi
+}
+
+do_install(){
+	install -d ${D}/opt/ltp/
+	oe_runmake DESTDIR=${D} SKIP_IDCHECK=1 install
+	
+	# Copy POSIX test suite into ${D}/opt/ltp/testcases by manual
+	cp -r testcases/open_posix_testsuite ${D}/opt/ltp/testcases
+
+	# We need to remove all scripts which depend on /usr/bin/expect, since expect is not supported in poky
+	# We will add expect for enhancement in future
+	find ${D} -type f -print | xargs grep "\!.*\/usr\/bin\/expect" | awk -F":" '{print $1}' | xargs rm -f
+}
-- 
1.7.1




^ permalink raw reply related	[flat|nested] 7+ messages in thread
end of thread, other threads:[~2011-12-21 16:31 UTC | newest]

Thread overview: 7+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2011-12-02 15:48 [PATCH 0/3] ltp: Add recipe from OE Jiajun Xu
2011-12-02 15:54 ` [PATCH 1/3] " Jiajun Xu
2011-12-03 23:39   ` Saul Wold
2011-12-21 15:49     ` Xu, Jiajun
2011-12-02 15:54 ` [PATCH 2/3] distro_tracking_fields: add information for ltp Jiajun Xu
2011-12-02 15:54 ` [PATCH 3/3] task-core-tools: add ltp to testapps list Jiajun Xu
2011-12-21 16:45 [PATCH 0/3] ltp: Add recipe from OE Jiajun Xu
2011-12-21 16:45 ` [PATCH 1/3] " Jiajun Xu

This is an external index of several public inboxes,
see mirroring instructions on how to clone and mirror
all data and code used by this external index.