[meta-python][RFC] python3-kivy

* [meta-python][RFC] python3-kivy
@ 2021-08-26  3:04 William Huang
  2021-08-26 17:17 ` [oe] " Khem Raj
  0 siblings, 1 reply; 3+ messages in thread
From: William Huang @ 2021-08-26  3:04 UTC (permalink / raw)
  To: openembedded-devel

[-- Attachment #1.1: Type: text/plain, Size: 628 bytes --]

Hello,
I would like to request for comments on a Kivy recipe. Not sure how I should include the recipe but I added it as an attachment for now. I've also included a recipe that installs example programs into /usr/share/kivy-examples/examples.

I managed to get it running on a Rockchip rk3399 in a X environment, as well as on a imx8 in a Wayland environment, although I did need to reconfigure libsdl2 to use GLES libraries and remove X11 package in the case of the imx8.

Any feedback would be great! Not sure if the recipe would be good enough to be included in the meta-python layer as well.

Thanks,
William Huang

[-- Attachment #1.2: Type: text/html, Size: 666 bytes --]

[-- Attachment #2: python3-kivy_2.0.0.bb --]
[-- Type: application/octet-stream, Size: 1748 bytes --]

SUMMARY = "Recipie to embedded the Python PiP Package Kivy"
HOMEPAGE = "https://kivy.org/"
LICENSE = "MIT"

LIC_FILES_CHKSUM = "file://LICENSE;md5=f0c851d60495c7e27225a819e179208a"

inherit setuptools3

SRC_URI = "\
    git://github.com/kivy/kivy.git;protocol=git;\
    "

# Kivy's setup files only look for GLES libraries for android, iOs, Raspberry Pi, and mali-based OS's
# We need to patch the setup file to tell Kivy setup that our machine has GLES libaries installed as well
SRC_URI += " \
    file://0001-add-support-for-glesv2.patch \
"
SRCREV = "dedcb6bcabe3d8d6758dcee607e8c33b174d782b"

S = "${WORKDIR}/git"

USE_WAYLAND = "${@bb.utils.contains('DISTRO_FEATURES', 'wayland', '1', '0', d)}"
export USE_WAYLAND

# if using Wayland, let's use pure Wayland (and not XWayland)
# so do not build using X11 flag when we detect Wayland
USE_X11 = " \
    ${@bb.utils.contains('DISTRO_FEATURES', 'wayland',  '0', \
       bb.utils.contains('DISTRO_FEATURES', 'x11',      '1', \
                                                        '0', d), d)}"
export USE_X11

# Use OpenGL ES 2.0 library
KIVY_GRAPHICS = "gles"
export KIVY_GRAPHICS

KIVY_CROSS_SYSROOT="${WORKDIR}/recipe-sysroot"
export KIVY_CROSS_SYSROOT

DEPENDS += " \
    gstreamer1.0 \
    gstreamer1.0-python \
    libsdl2 \
    libsdl2-ttf \
    libsdl2-image \
    libsdl2-mixer \
    pango \
    python3 \
    python3-cython-native \
"

RDEPENDS_${PN} = " \
    gstreamer1.0 \
    gstreamer1.0-python \
    libsdl2 \
    libsdl2-ttf \
    libsdl2-image \
    libsdl2-mixer \
    pango \
    python3 \
    python3-docutils \
    python3-fcntl \
    python3-image \
    python3-pillow \
    python3-pygments \
"

# remove kivy-examples
do_install_append() {
    rm -rf ${D}/usr/share
}

[-- Attachment #3: kivy-examples_2.0.0.bb --]
[-- Type: application/octet-stream, Size: 511 bytes --]

SUMMARY = "Recipie to embedded the Python PiP Package Kivy"
HOMEPAGE = "https://kivy.org/"
LICENSE = "MIT"

LIC_FILES_CHKSUM = "file://LICENSE;md5=f0c851d60495c7e27225a819e179208a"

SRC_URI = "\
    git://github.com/kivy/kivy.git;protocol=git;\
    "
SRCREV = "dedcb6bcabe3d8d6758dcee607e8c33b174d782b"

S = "${WORKDIR}/git"

do_compile() {
}

do_configure() {
}

do_install() {
    install -d ${D}/usr/share/kivy-examples
    cp -r ${S}/examples ${D}/usr/share/kivy-examples
}

FILES_${PN} += "${S}/examples"

^ permalink raw reply	[flat|nested] 3+ messages in thread