[cocci] Matching the size of an array

* [cocci] Matching the size of an array
@ 2023-06-06  6:14 Yann Droneaud
  2023-06-06 16:23 ` Julia Lawall
  2023-06-06 17:15 ` Markus Elfring
  0 siblings, 2 replies; 3+ messages in thread
From: Yann Droneaud @ 2023-06-06  6:14 UTC (permalink / raw)
  To: cocci

[-- Attachment #1: Type: text/plain, Size: 713 bytes --]

Hi,

I've managed to use coccinelle to replace something like:

char array[123]

snprintf(array, 123, ...);

with:

#define SNPRINTF(array, fmt, ...) snprintf(array, sizeof(array), fmt, ## 
__VA_ARGS__)

char array[123];

SNPRINTF(array, ...)

The difficult part for me was to figure how to match array and size within
structures, part of typedef or not, anonymous or not, accessed through 
pointer
or not.

And I'm not proud of SmPL I wrote. See the attached monster.

I'm sure I've missed some ways to use simpler constructs.

The example can be found here, with the test case:

https://gitlab.com/ydroneaud/snprintf.cocci/

I hope someone could give some hints to simplify my mess.

Regards

-- 
Yann Droneaud

[-- Attachment #2: SNPRINTF.cocci --]
[-- Type: text/plain, Size: 2670 bytes --]

@@
expression DST;
@@
- snprintf(DST, sizeof(DST),
+ SNPRINTF(DST,
  ...);

// match an array declared as a variable
@as_variable@
identifier DST;
expression DSTSIZE;
@@
(
  char DST[DSTSIZE];
|
  char DST[DSTSIZE] = ...;
)

@@
identifier as_variable.DST;
expression as_variable.DSTSIZE;
@@
- snprintf(DST, DSTSIZE,
+ SNPRINTF(DST,
  ...);

// match a structure
@in_struct@
identifier STRUCT;
identifier DST;
expression DSTSIZE;
@@
  struct STRUCT {
      ...
      char DST[DSTSIZE];
      ...
  }

@@
identifier in_struct.STRUCT;
struct STRUCT VAR;
identifier in_struct.DST;
expression in_struct.DSTSIZE;
@@
- snprintf(VAR.DST, DSTSIZE,
+ SNPRINTF(VAR.DST,
  ...);

@@
identifier in_struct.STRUCT;
struct STRUCT *PTR;
identifier in_struct.DST;
expression in_struct.DSTSIZE;
@@
- snprintf(PTR->DST, DSTSIZE,
+ SNPRINTF(PTR->DST,
  ...);

// match a structure used to declare a new type
@as_typedef@
identifier in_struct.STRUCT;
type TYPE;
@@
  typedef struct STRUCT TYPE;

@@
type as_typedef.TYPE;
TYPE VAR;
identifier in_struct.DST;
expression in_struct.DSTSIZE;
@@
- snprintf(VAR.DST, DSTSIZE,
+ SNPRINTF(VAR.DST,
  ...);

@@
type as_typedef.TYPE;
TYPE *PTR;
identifier in_struct.DST;
expression in_struct.DSTSIZE;
@@
- snprintf(PTR->DST, DSTSIZE,
+ SNPRINTF(PTR->DST,
  ...);

// match an anonymous structure used to declare a new type
@in_anon_typedef@
identifier DST;
expression DSTSIZE;
type TYPE;
@@
  typedef struct
  {
  ...
  char DST[DSTSIZE];
  ...
  } TYPE;

@@
type in_anon_typedef.TYPE;
TYPE VAR;
identifier in_anon_typedef.DST;
expression in_anon_typedef.DSTSIZE;
@@
- snprintf(VAR.DST, DSTSIZE,
+ SNPRINTF(VAR.DST,
  ...);

@@
type in_anon_typedef.TYPE;
TYPE *PTR;
identifier in_anon_typedef.DST;
expression in_anon_typedef.DSTSIZE;
@@
- snprintf(PTR->DST, DSTSIZE,
+ SNPRINTF(PTR->DST,
  ...);

// match a named structure used to declare a new type
@in_typedef@
identifier STRUCT;
identifier DST;
expression DSTSIZE;
type TYPE;
@@
  typedef struct STRUCT
  {
  ...
  char DST[DSTSIZE];
  ...
  } TYPE;

@@
type in_typedef.TYPE;
TYPE VAR;
identifier in_typedef.DST;
expression in_typedef.DSTSIZE;
@@
- snprintf(VAR.DST, DSTSIZE,
+ SNPRINTF(VAR.DST,
  ...);

@@
type in_typedef.TYPE;
TYPE *PTR;
identifier in_typedef.DST;
expression in_typedef.DSTSIZE;
@@
- snprintf(PTR->DST, DSTSIZE,
+ SNPRINTF(PTR->DST,
  ...);

// match an anonymous structure used to declare a new type
@in_anon_var@
identifier DST;
expression DSTSIZE;
identifier VAR;
@@
  struct
  {
  ...
  char DST[DSTSIZE];
  ...
  } VAR;

@@
identifier in_anon_var.VAR;
identifier in_anon_var.DST;
expression in_anon_var.DSTSIZE;
@@
- snprintf(VAR.DST, DSTSIZE,
+ SNPRINTF(VAR.DST,
  ...);

^ permalink raw reply	[flat|nested] 3+ messages in thread