RE: [PATCH v4] gstreamer1.0-plugins-bad/ugly: use the GPL-2.0-or-later only when it is in use

[Peter Kjellerstedt <peter.kjellerstedt@axis.com>]

> -----Original Message-----
> From: Jose Quaresma <quaresma.jose@gmail.com>
> Sent: den 7 mars 2022 09:59
> To: openembedded-core@lists.openembedded.org
> Cc: Jose Quaresma <quaresma.jose@gmail.com>; Peter Kjellerstedt <peter.kjellerstedt@axis.com>
> Subject: [PATCH v4] gstreamer1.0-plugins-bad/ugly: use the GPL-2.0-or-later only when it is in use
> 
> Since all gstreamer modules uses LGPLv2.1 with exceptions
> for some plugins in bad and ugly modules that has GPLv2+.
> 
> For the GPLv2+ this patch set the license only for each plugin
> that is affected by this license. The commercial LICENSE_FLAGS
> is enabled if any of the previous plugins is builded.
> 
> CC: Peter Kjellerstedt <peter.kjellerstedt@axis.com>
> Signed-off-by: Jose Quaresma <quaresma.jose@gmail.com>
> ---
>  .../gstreamer1.0-plugins-bad_1.20.0.bb        |  5 ++--
>  .../gstreamer1.0-plugins-license.inc          | 26 +++++++++++++++++++
>  .../gstreamer1.0-plugins-ugly_1.20.0.bb       |  8 +++---
>  3 files changed, 33 insertions(+), 6 deletions(-)
>  create mode 100644 meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-license.inc
> 
> diff --git a/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-bad_1.20.0.bb b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-bad_1.20.0.bb
> index 44532222fa..17799040ef 100644
> --- a/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-bad_1.20.0.bb
> +++ b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-bad_1.20.0.bb
> @@ -1,4 +1,5 @@
>  require gstreamer1.0-plugins-common.inc
> +require gstreamer1.0-plugins-license.inc
> 
>  DESCRIPTION = "'Bad' GStreamer plugins and helper libraries "
>  HOMEPAGE = "https://gstreamer.freedesktop.org/"
> @@ -92,8 +93,8 @@ PACKAGECONFIG[webrtcdsp]       = "-Dwebrtcdsp=enabled,-Dwebrtcdsp=disabled,webrt
>  PACKAGECONFIG[zbar]            = "-Dzbar=enabled,-Dzbar=disabled,zbar"
>  PACKAGECONFIG[x11]             = "-Dx11=enabled,-Dx11=disabled,libxcb libxkbcommon"
> 
> -# GPL - only built if gpl option is also enabled!
> -PACKAGECONFIG[gpl]             = "-Dgpl=enabled,-Dgpl=disabled"
> +GSTREAMER_GPL = "${@bb.utils.filter('PACKAGECONFIG', 'faad resindvd x265', d)}"

Seems a bit odd to have this variable in the middle of 
the PACKAGECONFIGs.

> +
>  PACKAGECONFIG[faad]            = "-Dfaad=enabled,-Dfaad=disabled,faad2"
>  PACKAGECONFIG[resindvd]        = "-Dresindvd=enabled,-Dresindvd=disabled,libdvdread libdvdnav"
>  PACKAGECONFIG[x265]            = "-Dx265=enabled,-Dx265=disabled,x265"
> diff --git a/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-license.inc b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-license.inc
> new file mode 100644
> index 0000000000..23a42d9c24
> --- /dev/null
> +++ b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-license.inc
> @@ -0,0 +1,26 @@
> +# This .inc file contains functionality for automatically setting
> +# the common license of all plugins so we can overwride some of them
> +#
> +# This is mainly used by the gstreamer1.0-plugins-* plugin set recipes,
> +# but can be used in any recipe that produces GStreamer plugins.
> +
> +PACKAGESPLITFUNCS:append = " set_gstreamer_license "
> +
> +python set_gstreamer_license () {
> +    import oe.utils
> +    pn = d.getVar('PN') + '-'
> +    gpl_plugins_names = [pn+plugin for plugin in d.getVar('GSTREAMER_GPL').split()]
> +    for pkg in oe.utils.packages_filter_out_system(d):
> +        if pkg in gpl_plugins_names:
> +            d.setVar('LICENSE:' + pkg, 'GPL-2.0-or-later')
> +        else:
> +            d.setVar('LICENSE:' + pkg, 'LGPL-2.1-or-later')
> +}
> +
> +EXTRA_OEMESON += " \
> +    ${@bb.utils.contains_any('PACKAGECONFIG', "${GSTREAMER_GPL}", '-Dgpl=enabled', '-Dgpl=disabled', d)} \
> +    "
> +
> +LICENSE_FLAGS = " \
> +    ${@bb.utils.contains_any('PACKAGECONFIG', "${GSTREAMER_GPL}", 'commercial', '', d)} \
> +    "
> diff --git a/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-ugly_1.20.0.bb b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-ugly_1.20.0.bb
> index 9b6f80aa89..577ba16af7 100644
> --- a/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-ugly_1.20.0.bb
> +++ b/meta/recipes-multimedia/gstreamer/gstreamer1.0-plugins-ugly_1.20.0.bb
> @@ -1,4 +1,5 @@
>  require gstreamer1.0-plugins-common.inc
> +require gstreamer1.0-plugins-license.inc
> 
>  DESCRIPTION = "'Ugly GStreamer plugins"
>  HOMEPAGE = "https://gstreamer.freedesktop.org/"
> @@ -8,7 +9,6 @@ LIC_FILES_CHKSUM = "file://COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
> 
> file://tests/check/elements/xingmux.c;beginline=1;endline=21;md5=4c771b8af188724855cb99cadd390068"
> 
>  LICENSE = "LGPL-2.1-or-later & GPL-2.0-or-later"
> -LICENSE_FLAGS = "commercial"

I still think this is wrong. I.e., the commercial flag is not 
related to a plugin using GPL or not, but rather the fact that it 
is in ugly. E.g., the reason may be patent considerations and 
can apply to any of the plugins regardless of license.

> 
>  SRC_URI = " \
>              https://gstreamer.freedesktop.org/src/gst-plugins-ugly/gst-plugins-ugly-${PV}.tar.xz \
> @@ -23,14 +23,14 @@ GST_PLUGIN_SET_HAS_EXAMPLES = "0"
> 
>  PACKAGECONFIG ??= " \
>      ${GSTREAMER_ORC} \
> -    gpl a52dec mpeg2dec \
> +    a52dec mpeg2dec \
>  "
> 
>  PACKAGECONFIG[amrnb]    = "-Damrnb=enabled,-Damrnb=disabled,opencore-amr"
>  PACKAGECONFIG[amrwb]    = "-Damrwbdec=enabled,-Damrwbdec=disabled,opencore-amr"
> 
> -# GPL - only built if gpl option is also enabled!
> -PACKAGECONFIG[gpl]      = "-Dgpl=enabled,-Dgpl=disabled"
> +GSTREAMER_GPL = "${@bb.utils.filter('PACKAGECONFIG', 'cdio a52dec dvdread mpeg2dec x264', d)}"
> +
>  PACKAGECONFIG[cdio]     = "-Dcdio=enabled,-Dcdio=disabled,libcdio"
>  PACKAGECONFIG[a52dec]   = "-Da52dec=enabled,-Da52dec=disabled,liba52"
>  PACKAGECONFIG[dvdread]  = "-Ddvdread=enabled,-Ddvdread=disabled,libdvdread"
> --
> 2.35.1

//Peter