[PATCH] tidl-api: Initial release v01.00.00

* [PATCH] tidl-api: Initial release v01.00.00
@ 2018-05-31 15:14 Yuan Zhao
  2018-06-20 12:21 ` [EXTERNAL] " Jacob Stiffler
  0 siblings, 1 reply; 2+ messages in thread
From: Yuan Zhao @ 2018-05-31 15:14 UTC (permalink / raw)
  To: meta-arago

- Recipes for building from repository for TI Deep Learning (TIDL) API.
  Repo contains the API, examples, and a TIDL network viewer.
- Recipes: tidl-examples, tidl-viewer, tidl-viewer-native

Signed-off-by: Yuan Zhao <yuanzhao@ti.com>
---
 meta-arago-extras/recipes-ti/tidl-api/tidl-api.inc | 11 +++++
 .../recipes-ti/tidl-api/tidl-examples_git.bb       | 47 ++++++++++++++++++++++
 .../recipes-ti/tidl-api/tidl-viewer_git.bb         | 32 +++++++++++++++
 3 files changed, 90 insertions(+)
 create mode 100644 meta-arago-extras/recipes-ti/tidl-api/tidl-api.inc
 create mode 100644 meta-arago-extras/recipes-ti/tidl-api/tidl-examples_git.bb
 create mode 100644 meta-arago-extras/recipes-ti/tidl-api/tidl-viewer_git.bb

diff --git a/meta-arago-extras/recipes-ti/tidl-api/tidl-api.inc b/meta-arago-extras/recipes-ti/tidl-api/tidl-api.inc
new file mode 100644
index 00000000..d266611c
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/tidl-api/tidl-api.inc
@@ -0,0 +1,11 @@
+PV = "1.0.0.0"
+INC_PR = "r0"
+
+LIC_FILES_CHKSUM = "file://tidl_api_manifest.html;md5=ae816cc40db02fe06193212437ad00e8"
+
+GIT_URI = "git://git.ti.com/tidl/tidl-api.git"
+GIT_PROTOCOL = "git"
+BRANCH = "master"
+
+SRC_URI = "${GIT_URI};protocol=${GIT_PROTOCOL};branch=${BRANCH}"
+SRCREV = "d6326ad29c9ed4b79ebf3e0f588f247ed2cf3d2e"
diff --git a/meta-arago-extras/recipes-ti/tidl-api/tidl-examples_git.bb b/meta-arago-extras/recipes-ti/tidl-api/tidl-examples_git.bb
new file mode 100644
index 00000000..be9bb65f
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/tidl-api/tidl-examples_git.bb
@@ -0,0 +1,47 @@
+SUMMARY = "TIDL API and examples"
+DESCRIPTION = "TIDL API and examples of API usage. Refer TIDL API User's Guide for details."
+HOMEPAGE = "http://software-dl.ti.com/mctools/docs/tidl-api/intro.html"
+LICENSE = "BSD"
+
+include tidl-api.inc
+require recipes-ti/includes/ti-paths.inc
+
+PR = "${INC_PR}.0"
+
+COMPATIBLE_MACHINE = "am57xx-evm|am57xx-hs-evm"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+DEPENDS = "opencv opencl opencl-monitor ti-cgt6x-native clocl-native"
+
+RDEPENDS_${PN} += " opencl-runtime opencv"
+
+S = "${WORKDIR}/git"
+
+EXTRA_OEMAKE = " -C ${S}/examples \
+                 TARGET_ROOTDIR=${STAGING_DIR_HOST} \
+                 TI_OCL_CGT_INSTALL=${STAGING_DIR_NATIVE}/usr/share/ti/cgt-c6x \
+"
+
+do_compile() {
+  oe_runmake
+}
+
+CP_ARGS="-Prf --preserve=mode,timestamps --no-preserve=ownership"
+
+do_install() {
+    install -d ${D}${datadir}/ti/tidl-api
+    install -d ${D}${datadir}/ti/tidl-api/examples
+    install -d ${D}${datadir}/ti/tidl-api/tidl_api
+    install -d ${D}${datadir}/ti/tidl-api/viewer
+    cp ${CP_ARGS} ${S}/examples/* ${D}${datadir}/ti/tidl-api/examples/
+    cp ${CP_ARGS} ${S}/tidl_api/* ${D}${datadir}/ti/tidl-api/tidl_api/
+    cp ${CP_ARGS} ${S}/viewer/* ${D}${datadir}/ti/tidl-api/viewer/
+    install ${S}/readme.md ${D}${datadir}/ti/tidl-api/
+}
+
+FILES_${PN} += "\
+    ${datadir}/ti/tidl-api \
+"
+
+
+INSANE_SKIP_${PN} = "arch ldflags textrel staticdev"
diff --git a/meta-arago-extras/recipes-ti/tidl-api/tidl-viewer_git.bb b/meta-arago-extras/recipes-ti/tidl-api/tidl-viewer_git.bb
new file mode 100644
index 00000000..3c761747
--- /dev/null
+++ b/meta-arago-extras/recipes-ti/tidl-api/tidl-viewer_git.bb
@@ -0,0 +1,32 @@
+SUMMARY = "TIDL Network Viewer"
+DESCRIPTION = "TIDL Network viewer using dot and graphviz"
+HOMEPAGE = "http://software-dl.ti.com/mctools/docs/tidl-api/intro.html"
+LICENSE = "BSD"
+
+include tidl-api.inc
+
+PR = "${INC_PR}.0"
+
+DEPENDS = "boost boost-native ti-cgt6x-native clocl-native"
+
+S = "${WORKDIR}/git"
+
+TARGET_class-target = "arm"
+TARGET_class-native = "x86"
+TARGET_class-nativesdk = "x86"
+
+EXTRA_OEMAKE = " -C ${S}/viewer \
+                 TARGET=${TARGET} \
+                 TARGET_ROOTDIR=${STAGING_DIR_HOST} \
+"
+
+do_compile() {
+  oe_runmake
+}
+
+do_install() {
+  install -d ${D}${bindir}
+  install -m 755 ${S}/viewer/${TARGET}/tidl_viewer ${D}${bindir}
+}
+
+BBCLASSEXTEND = "native nativesdk"
-- 
2.14.1



^ permalink raw reply related	[flat|nested] 2+ messages in thread