DEPENDS problem with core-image-full-cmdline

DEPENDS problem with core-image-full-cmdline

[Jonathan Haws]

[-- Attachment #1: Type: text/plain, Size: 1769 bytes --]

I'm working on a recipe for batman-adv, which depends on libnl at build 
time.

I've attached my recipe for batman-adv.  It's pretty straightforward, 
but the DEPENDS variable doesn't seem to work when I build 
core-image-full-cmdline.  If I clean both libnl and batman-adv, then 
bitbake batman-adv, it works as expected - libnl is built first, 
followed by batman-adv.

However, when building core-image-full-cmdline, I get the following errors.

Thoughts?

Thanks!
Jon


ERROR: oe_runmake failed
ERROR: Function failed: do_configure (log file is located at 
/opt/yocto/poky/build-vbox/tmp/work/corei7-64-sigma-linux/batctl/2016.1_git7a3d563466f368b9b50191f441b775bae46a77ca-r0/temp/log.do_configure.98063)
ERROR: Logfile of failure stored in: 
/opt/yocto/poky/build-vbox/tmp/work/corei7-64-sigma-linux/batctl/2016.1_git7a3d563466f368b9b50191f441b775bae46a77ca-r0/temp/log.do_configure.98063
Log data follows:
| DEBUG: Executing python function sysroot_cleansstate
| DEBUG: Python function sysroot_cleansstate finished
| DEBUG: Executing shell function do_configure
| NOTE: make -e MAKEFLAGS= clean
| Makefile:56: *** No libnl-3.0 development libraries found!.  Stop.
| ERROR: oe_runmake failed
| ERROR: Function failed: do_configure (log file is located at 
/opt/yocto/poky/build-vbox/tmp/work/corei7-64-sigma-linux/batctl/2016.1_git7a3d563466f368b9b50191f441b775bae46a77ca-r0/temp/log.do_configure.98063)
ERROR: Task 580 
(/opt/yocto/poky/meta-sdl/meta-sigma/recipes-batman/batman/batctl_2016.1.bb, 
do_configure) failed with exit code '1'
NOTE: Tasks Summary: Attempted 2290 tasks of which 2282 didn't need to 
be rerun and 1 failed.



-- 
Jonathan R. Haws
Embedded Engineer
Space Dynamics Laboratory
jhaws@sdl.usu.edu

[-- Attachment #2: batman-adv_2016.1.bb --]
[-- Type: text/plain, Size: 806 bytes --]

SUMMARY = "B.A.T.M.A.N. Advanced Kernel Module"
DESCRIPTION = "Kernel module providing batman-adv mesh networking capabilities"
LICENSE = "GPLv3"
LIC_FILES_CHKSUM = "file://../COPYING;md5=d32239bcb673463ab874e80d47fae504"

inherit module

DEPENDS = " libnl"
RDEPENDS_${PN} = " kernel-module-libcrc32c kernel-module-bridge"
S = "${WORKDIR}/git"

SRCREV = "01a3aa4396e3dacdee29a1ce96057f51d02d4dd0"
SRC_URI = "git://git.open-mesh.org/batman-adv.git \
           file://COPYING \
           file://0000_batmav-adv_makefile-KERNELPATH.patch;patchdir=${S};striplevel=0 \
          "

PV = "2016.1_git${SRCREV}"

# The inherit of module.bbclass will automatically name module packages with
# "kernel-module-" prefix as required by the oe-core build environment.
KERNEL_MODULE_AUTOLOAD += " libcrc32c batman-adv"

Re: DEPENDS problem with core-image-full-cmdline

[Burton, Ross]

[-- Attachment #1: Type: text/plain, Size: 242 bytes --]

On 26 May 2016 at 17:01, Jonathan Haws <Jonathan.Haws@sdl.usu.edu> wrote:

> However, when building core-image-full-cmdline, I get the following errors.
>

The error is in the batctl recipe, does that also have a DEPENDS=libnl?

Ross

[-- Attachment #2: Type: text/html, Size: 654 bytes --]

Re: DEPENDS problem with core-image-full-cmdline

[Jonathan Haws]

[-- Attachment #1: Type: text/plain, Size: 2017 bytes --]

>     However, when building core-image-full-cmdline, I get the following
>     errors.
>
>
> The error is in the batctl recipe, does that also have a DEPENDS=libnl?
>

Oh geez...I feel sheepish!

Attached is my updated batctl recipe - still giving the same errors.

ERROR: oe_runmake failed
ERROR: Function failed: do_compile (log file is located at 
/opt/yocto/poky/build-vbox/tmp/work/corei7-64-sigma-linux/batctl/2016.1_git7a3d563466f368b9b50191f441b775bae46a77ca-r0/temp/log.do_compile.68518)
ERROR: Logfile of failure stored in: 
/opt/yocto/poky/build-vbox/tmp/work/corei7-64-sigma-linux/batctl/2016.1_git7a3d563466f368b9b50191f441b775bae46a77ca-r0/temp/log.do_compile.68518
Log data follows:
| DEBUG: Executing shell function do_compile
| NOTE: make -j 32 -e MAKEFLAGS=
| Makefile:56: *** No libnl-3.0 development libraries found!.  Stop.
| ERROR: oe_runmake failed
| ERROR: Function failed: do_compile (log file is located at 
/opt/yocto/poky/build-vbox/tmp/work/corei7-64-sigma-linux/batctl/2016.1_git7a3d563466f368b9b50191f441b775bae46a77ca-r0/temp/log.do_compile.68518)
ERROR: Task 581 
(/opt/yocto/poky/meta-sdl/meta-sigma/recipes-batman/batman/batctl_2016.1.bb, 
do_compile) failed with exit code '1'
NOTE: Tasks Summary: Attempted 3480 tasks of which 3473 didn't need to 
be rerun and 1 failed.


I did find that if I do:

DEPENDS += " batman-adv libnl"

instead of

DEPENDS_${PN} += " batman-adv libnl"

the problem goes away.  Can someone explain the difference?  As I 
understood it, _${PN} basically created a DEPENDS variable for this 
specific package and avoided touching others.  Is that not the case? 
Can someone point me to the right section in the docs that would 
enlighten me?

Thanks!

As an aside, with this DEPENDS fix I have a set of fully functional 
recipes for batman-adv, batctl, and alfred if anyone is interested.  I 
wasn't able to find any online that were up to date with the latest 
Yocto releases and latest batman-adv.



[-- Attachment #2: batctl_2016.1.bb --]
[-- Type: text/plain, Size: 739 bytes --]

DESCRIPTION = "Control application for B.A.T.M.A.N. routing protocol kernel module for multi-hop ad-hoc mesh networks."
HOMEPAGE = "http://www.open-mesh.net/"
SECTION = "console/network"
PRIORITY = "optional"
LICENSE = "GPLv3"
LIC_FILES_CHKSUM = "file://../COPYING;md5=d32239bcb673463ab874e80d47fae504"

DEPENDS += " batman-adv libnl"
RDEPENDS_${PN} += " kernel-module-batman-adv"
S = "${WORKDIR}/git"

SRCREV = "7a3d563466f368b9b50191f441b775bae46a77ca"
SRC_URI = "git://git.open-mesh.org/batctl.git \
           file://COPYING \
           file://0000_batctl_makefile-flags.patch \
          "

PV = "2016.1_git${SRCREV}"

do_compile() {
  oe_runmake
}

do_install() {
  install -d ${D}${bindir}
  install -m 0755 batctl ${D}${bindir}
}

Re: DEPENDS problem with core-image-full-cmdline

[Burton, Ross]

[-- Attachment #1: Type: text/plain, Size: 661 bytes --]

On 26 May 2016 at 17:36, Jonathan Haws <Jonathan.Haws@sdl.usu.edu> wrote:

> I did find that if I do:
>
> DEPENDS += " batman-adv libnl"
>
> instead of
>
> DEPENDS_${PN} += " batman-adv libnl"
>

DEPENDS is built-time for the recipe, so the concept of per-package build
dependencies doesn't really make sense.

DEPENDS = "foo bar" are build dependencies
RDEPENDS_${PN} = "foo bar" are package-specific runtime dependencies.

If you have recipes that work, then submitting them to meta-oe or even just
uploading a layer onto github and then adding it to layers.openembedded.org
would be much appreciated so that others can find them.

Ross

[-- Attachment #2: Type: text/html, Size: 1323 bytes --]

Re: DEPENDS problem with core-image-full-cmdline

[Jonathan Haws]

> DEPENDS is built-time for the recipe, so the concept of per-package
> build dependencies doesn't really make sense.
>
> DEPENDS = "foo bar" are build dependencies
> RDEPENDS_${PN} = "foo bar" are package-specific runtime dependencies.

Ross, thanks for clearing that up.  Is there anything in the 
documentation that talks about that?  I've read through most of the docs 
and don't remember any details about that distinction.  Are there other 
variables that this applies to?

> If you have recipes that work, then submitting them to meta-oe or even
> just uploading a layer onto github and then adding it to
> layers.openembedded.org <http://layers.openembedded.org> would be much
> appreciated so that others can find them.

Sounds good.  Uploaded to my github account and layer posted to OE 
index.  I hope it helps someone else!

Jon

Re: DEPENDS problem with core-image-full-cmdline

[Burton, Ross]

[-- Attachment #1: Type: text/plain, Size: 767 bytes --]

On 26 May 2016 at 18:03, Jonathan Haws <Jonathan.Haws@sdl.usu.edu> wrote:

> > DEPENDS is built-time for the recipe, so the concept of per-package
> > build dependencies doesn't really make sense.
> >
> > DEPENDS = "foo bar" are build dependencies
> > RDEPENDS_${PN} = "foo bar" are package-specific runtime dependencies.
>
> Ross, thanks for clearing that up.  Is there anything in the
> documentation that talks about that?  I've read through most of the docs
> and don't remember any details about that distinction.  Are there other
> variables that this applies to?


The general rule is that the only time you use _${PN} or similar is when
the variable impacts a binary package, so FILES, RDEPENDS, RRECOMMENDS,
INSANE_SKIP and similar.

Ross

[-- Attachment #2: Type: text/html, Size: 1208 bytes --]

Re: DEPENDS problem with core-image-full-cmdline

[Paul Eggleton]

On Thu, 26 May 2016 17:03:13 Jonathan Haws wrote:
> > DEPENDS is built-time for the recipe, so the concept of per-package
> > build dependencies doesn't really make sense.
> > 
> > DEPENDS = "foo bar" are build dependencies
> > RDEPENDS_${PN} = "foo bar" are package-specific runtime dependencies.
> 
> Ross, thanks for clearing that up.  Is there anything in the
> documentation that talks about that?  I've read through most of the docs
> and don't remember any details about that distinction.

I guess we don't cover that explicitly, other than in the reference manual
entries for each variable. We probably need a small section on dependencies
in the "Writing a new Recipe" section:

  http://www.yoctoproject.org/docs/current/dev-manual/dev-manual.html#new-recipe-writing-a-new-recipe

That can cover the difference between build-time and runtime dependencies
and the usage of DEPENDS and RDEPENDS respectively.

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre

Re: DEPENDS problem with core-image-full-cmdline

[Paul Eggleton]

On Fri, 27 May 2016 09:01:31 Paul Eggleton wrote:
> On Thu, 26 May 2016 17:03:13 Jonathan Haws wrote:
> > > DEPENDS is built-time for the recipe, so the concept of per-package
> > > build dependencies doesn't really make sense.
> > > 
> > > DEPENDS = "foo bar" are build dependencies
> > > RDEPENDS_${PN} = "foo bar" are package-specific runtime dependencies.
> > 
> > Ross, thanks for clearing that up.  Is there anything in the
> > documentation that talks about that?  I've read through most of the docs
> > and don't remember any details about that distinction.
> 
> I guess we don't cover that explicitly, other than in the reference manual
> entries for each variable. We probably need a small section on dependencies
> in the "Writing a new Recipe" section:
> 
>  
> http://www.yoctoproject.org/docs/current/dev-manual/dev-manual.html#new-rec
> ipe-writing-a-new-recipe
> 
> That can cover the difference between build-time and runtime dependencies
> and the usage of DEPENDS and RDEPENDS respectively.

FYI at Scott's suggestion I've filed a bug to cover updating the docs:

https://bugzilla.yoctoproject.org/show_bug.cgi?id=9679

Cheers,
Paul

-- 

Paul Eggleton
Intel Open Source Technology Centre

Re: DEPENDS problem with core-image-full-cmdline

[Jonathan Haws]

>> I guess we don't cover that explicitly, other than in the reference manual
>> entries for each variable. We probably need a small section on dependencies
>> in the "Writing a new Recipe" section:
>>
>>
>> http://www.yoctoproject.org/docs/current/dev-manual/dev-manual.html#new-rec
>> ipe-writing-a-new-recipe
>>
>> That can cover the difference between build-time and runtime dependencies
>> and the usage of DEPENDS and RDEPENDS respectively.
>
> FYI at Scott's suggestion I've filed a bug to cover updating the docs:
>
> https://bugzilla.yoctoproject.org/show_bug.cgi?id=9679

This will be very helpful. Thanks all!