Re: [PATCH v2 1/2] Add project-wide .vimrc configuration

[Christian Brabandt <cb@256bit.org>]

Hi,

Felipe Contreras schrieb am Mittwoch, den 09. Dezember 2020:

> +augroup git
> +	au BufRead,BufNewFile */Documentation/*.txt set filetype=asciidoc
> +
> +	au FileType c setl noexpandtab tabstop=8 shiftwidth=0 cino=(s,:0,l1,t0
> +	au FileType sh setl noexpandtab tabstop=8 shiftwidth=0
> +	au FileType perl setl noexpandtab tabstop=8 shiftwidth=0
> +	au FileType asciidoc setl noexpandtab tabstop=8 shiftwidth=0 autoindent
> +augroup END

This will set filetype specific options. So after this file has been 
loaded, it will set e.g. set tabstop and shiftwidth options for 
filetypes outside of the git project.

Shouldn't this only apply to files inside the git code repository?

> +
> +" vim: noexpandtab tabstop=8 shiftwidth=0
> diff --git a/contrib/vim/plugin/gitvimrc.vim b/contrib/vim/plugin/gitvimrc.vim
> new file mode 100644
> index 0000000000..c3946e5410
> --- /dev/null
> +++ b/contrib/vim/plugin/gitvimrc.vim
> @@ -0,0 +1,21 @@
> +let s:gitvimrc_whitelist = get(g:, 'gitvimrc_whitelist', [])
> +
> +function LoadGitVimrc()
> +  let l:top = trim(system('git rev-parse --show-toplevel'))

trim needs at least vim 8.0.1630. Is this recent enough? Could also use 
systemlist()[0] which is available starting at vim 7.4.248 or just a 
simple split(system(), "\n")[0] which should be compatible with vim 7.

> +  if l:top == '' | return | endif
> +  let l:file = l:top . '/.vimrc'
> +  if !filereadable(l:file) | return | endif
> +
> +  let l:found = 0
> +  for l:pattern in s:gitvimrc_whitelist

You could directly use `get(g:, 'gitvimrc_whitelist', [])` directly, so 
the script local var s:gitvimrc_whitelist is not really needed.

> +    if (match(l:top, l:pattern) != -1)

This uses a regex match. Perhaps do a string comparsion? If this is 
needed, consider adding "\C" to force matching case and perhaps also \V 
to force a literal match. Otherwise the options magic, ignorecase, 
smartcase etc are applied to the matching.

> +      let l:found = 1
> +      break
> +    endif
> +  endfor
> +  if !l:found | return | endif
> +
> +  exec 'source ' . fnameescape(l:file)
> +endf
> +
> +call LoadGitVimrc()

On the style: I personally dislike the `l:` prefix for function local 
variables, as this does not add anything. But perhaps this is just my 
personal preference.

Best,
Christian