From: Julia Lawall <Julia.Lawall@lip6.fr>
To: brcm80211-dev-list@broadcom.com
Cc: kernel-janitors@vger.kernel.org, alsa-devel@alsa-project.org,
coreteam@netfilter.org, netfilter@vger.kernel.org,
netfilter-devel@vger.kernel.org, linux-scsi@vger.kernel.org,
linux-kernel@vger.kernel.org, libertas-dev@lists.infradead.org,
linux-wireless@vger.kernel.org, netdev@vger.kernel.org,
linux-usb@vger.kernel.org, devel@driverdev.osuosl.org,
linux-raid@vger.kernel.org, oprofile-list@lists.sf.net,
linux-s390@vger.kernel.org
Subject: [PATCH 0/13] make return of 0 explicit
Date: Mon, 19 May 2014 06:31:02 +0200 [thread overview]
Message-ID: <1400473875-22228-1-git-send-email-Julia.Lawall@lip6.fr> (raw)
Sometimes a local variable is used as a return value in a case where the
return value is always 0. The result is more apparent if this variable is
just replaced by 0. This is done by the following semantic patch, although
some cleanups may be needed. (http://coccinelle.lip6.fr/)
// <smpl>
@r exists@
local idexpression ret;
identifier reti;
expression e;
position p;
@@
ret@reti = 0;
... when != \(ret = e\|ret &= e\|ret |= e\|ret += e\|ret -= e\|ret *= e\|ret ^= e\)
when != \(++ret\|--ret\|ret++\|ret--\)
when != &ret
return ret;@p
@bad1 exists@
expression e != 0;
local idexpression r.ret;
position r.p;
@@
\(ret = e\|ret &= e\|ret |= e\|ret += e\|ret -= e\|ret *= e\|ret ^= e\|++ret\|--ret\|ret++\|ret--\|&ret\)
...
return ret;@p
@bad2 exists@
identifier r.reti;
position r.p;
identifier f;
type T;
@@
f(...,T reti,...) {
...
return reti;@p
}
@change depends on !bad1 && !bad2@
position r.p;
local idexpression r.ret;
identifier f;
@@
f(...) { <+...
return
-ret
+0
;@p
...+> }
@rewrite@
local idexpression r.ret;
expression e;
position p;
identifier change.f;
@@
f(...) { <+...
\(ret@p = e\|&ret@p\)
...+> }
@depends on change@
local idexpression r.ret;
position p != rewrite.p;
identifier change.f;
@@
f(...) { <+...
(
break;
|
ret = 0;
... when exists
ret@p
... when any
|
- ret = 0;
)
...+> }
@depends on change@
identifier r.reti;
type T;
constant C;
identifier change.f;
@@
f(...) { ... when any
-T reti = C;
... when != reti
when strict
}
@depends on change@
identifier r.reti;
type T;
identifier change.f;
@@
f(...) { ... when any
-T reti;
... when != reti
when strict
}
// </smpl>
The first four rules detect cases where only 0 reaches a return. The
remaining rules clean up any variable initializations or declarations that
are made unnecessary by this change.
next reply other threads:[~2014-05-19 4:32 UTC|newest]
Thread overview: 10+ messages / expand[flat|nested] mbox.gz Atom feed top
2014-05-19 4:31 Julia Lawall [this message]
2014-05-19 4:31 ` [PATCH 1/13] libertas: make return of 0 explicit Julia Lawall
2014-05-19 7:43 ` walter harms
2014-05-19 12:45 ` Sergei Shtylyov
2014-05-19 17:25 ` Dan Williams
2014-05-22 12:32 ` [PATCH] libertas: fix return value when processing invalid packet Dan Williams
2014-05-22 21:57 ` James Cameron
2014-05-20 0:30 ` [PATCH 1/13] libertas: make return of 0 explicit Julia Lawall
2014-05-20 0:36 ` Julia Lawall
2014-05-19 4:31 ` [PATCH 12/13] brcmsmac: " Julia Lawall
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1400473875-22228-1-git-send-email-Julia.Lawall@lip6.fr \
--to=julia.lawall@lip6.fr \
--cc=alsa-devel@alsa-project.org \
--cc=brcm80211-dev-list@broadcom.com \
--cc=coreteam@netfilter.org \
--cc=devel@driverdev.osuosl.org \
--cc=kernel-janitors@vger.kernel.org \
--cc=libertas-dev@lists.infradead.org \
--cc=linux-kernel@vger.kernel.org \
--cc=linux-raid@vger.kernel.org \
--cc=linux-s390@vger.kernel.org \
--cc=linux-scsi@vger.kernel.org \
--cc=linux-usb@vger.kernel.org \
--cc=linux-wireless@vger.kernel.org \
--cc=netdev@vger.kernel.org \
--cc=netfilter-devel@vger.kernel.org \
--cc=netfilter@vger.kernel.org \
--cc=oprofile-list@lists.sf.net \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).