* [PATCH] scripts/coccinelle/misc/cstptr.cocci: semantic patch to check for PTR_ERR after reassignment
@ 2012-02-02 14:53 Julia Lawall
0 siblings, 0 replies; only message in thread
From: Julia Lawall @ 2012-02-02 14:53 UTC (permalink / raw)
To: Julia Lawall
Cc: kernel-janitors, Gilles Muller, Nicolas Palix, cocci,
linux-kernel, mmarek
From: Julia Lawall <Julia.Lawall@lip6.fr>
Signed-off-by: Julia Lawall <Julia.Lawall@lip6.fr>
---
scripts/coccinelle/misc/cstptr.cocci | 41 +++++++++++++++++++++++++++++++++++
1 file changed, 41 insertions(+)
diff --git a/scripts/coccinelle/misc/cstptr.cocci b/scripts/coccinelle/misc/cstptr.cocci
new file mode 100644
index 0000000..d425644
--- /dev/null
+++ b/scripts/coccinelle/misc/cstptr.cocci
@@ -0,0 +1,41 @@
+/// PTR_ERR should be applied before its argument is reassigned, typically
+/// to NULL
+///
+// Confidence: High
+// Copyright: (C) 2012 Julia Lawall, INRIA/LIP6. GPLv2.
+// Copyright: (C) 2012 Gilles Muller, INRIA/LiP6. GPLv2.
+// URL: http://coccinelle.lip6.fr/
+// Comments:
+// Options: -no_includes -include_headers
+
+virtual org
+virtual report
+virtual context
+
+@r exists@
+expression e,e1;
+constant c;
+position p1,p2;
+@@
+
+*e@p1 = c
+... when != e = e1
+ when != &e
+ when != true IS_ERR(e)
+*PTR_ERR@p2(e)
+
+@script:python depends on org@
+p1 << r.p1;
+p2 << r.p2;
+@@
+
+cocci.print_main("PTR_ERR",p2)
+cocci.print_secs("assignment",p1)
+
+@script:python depends on report@
+p1 << r.p1;
+p2 << r.p2;
+@@
+
+msg = "ERROR: PTR_ERR applied after initialization to constant on line %s" % (p1[0].line)
+coccilib.report.print_report(p2[0],msg)
^ permalink raw reply related [flat|nested] only message in thread
only message in thread, other threads:[~2012-02-02 14:53 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2012-02-02 14:53 [PATCH] scripts/coccinelle/misc/cstptr.cocci: semantic patch to check for PTR_ERR after reassignment Julia Lawall
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).