* [PATCH langdale 1/6] arm/edk2-basetools: Add edk2 base tool native recipe
2023-02-28 14:41 [PATCH langdale 0/6] Add UEFI capsule generation support gowtham.sureshkumar
@ 2023-02-28 14:41 ` gowtham.sureshkumar
2023-02-28 14:41 ` [PATCH langdale 2/6] arm-bsp/uefi_capsule: Add UEFI capsule generation class gowtham.sureshkumar
` (5 subsequent siblings)
6 siblings, 0 replies; 8+ messages in thread
From: gowtham.sureshkumar @ 2023-02-28 14:41 UTC (permalink / raw)
To: meta-arm, Ross.Burton; +Cc: nd, Gowtham Suresh Kumar, Jon Mason
From: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
The native recipe installs the UEFI capsule generation tool
along with the other base tools to native sysroot.
Signed-off-by: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
Signed-off-by: Jon Mason <jon.mason@arm.com>
---
.../edk2-basetools/edk2-basetools_202211.bb | 24 +++++++++++++++++++
1 file changed, 24 insertions(+)
create mode 100644 meta-arm/recipes-devtools/edk2-basetools/edk2-basetools_202211.bb
diff --git a/meta-arm/recipes-devtools/edk2-basetools/edk2-basetools_202211.bb b/meta-arm/recipes-devtools/edk2-basetools/edk2-basetools_202211.bb
new file mode 100644
index 00000000..c80fdae2
--- /dev/null
+++ b/meta-arm/recipes-devtools/edk2-basetools/edk2-basetools_202211.bb
@@ -0,0 +1,24 @@
+# Install EDK2 Base Tools in native sysroot. Currently the BaseTools are not
+# built, they are just copied to native sysroot. This is sufficient for
+# generating UEFI capsules as it only depends on some python scripts. Other
+# tools need to be built first before adding to sysroot.
+
+DESCRIPTION = "EDK2 Base Tools"
+LICENSE = "BSD-2-Clause-Patent"
+
+# EDK2
+SRC_URI = "git://github.com/tianocore/edk2.git;branch=master;protocol=https"
+LIC_FILES_CHKSUM = "file://License.txt;md5=2b415520383f7964e96700ae12b4570a"
+
+SRCREV = "fff6d81270b57ee786ea18ad74f43149b9f03494"
+
+S = "${WORKDIR}/git"
+
+RDEPENDS:${PN} += "python3-core"
+
+do_install () {
+ mkdir -p ${D}${bindir}/edk2-BaseTools
+ cp -r ${WORKDIR}/git/BaseTools/* ${D}${bindir}/edk2-BaseTools/
+}
+
+BBCLASSEXTEND = "native"
--
2.17.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [PATCH langdale 2/6] arm-bsp/uefi_capsule: Add UEFI capsule generation class
2023-02-28 14:41 [PATCH langdale 0/6] Add UEFI capsule generation support gowtham.sureshkumar
2023-02-28 14:41 ` [PATCH langdale 1/6] arm/edk2-basetools: Add edk2 base tool native recipe gowtham.sureshkumar
@ 2023-02-28 14:41 ` gowtham.sureshkumar
2023-02-28 14:41 ` [PATCH langdale 3/6] arm-bsp/corstone1000-image: Generate UEFI capsule for corstone1000 platform gowtham.sureshkumar
` (4 subsequent siblings)
6 siblings, 0 replies; 8+ messages in thread
From: gowtham.sureshkumar @ 2023-02-28 14:41 UTC (permalink / raw)
To: meta-arm, Ross.Burton; +Cc: nd, Gowtham Suresh Kumar, Jon Mason
From: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
This class currently supports only a single firmware binary. The
required capsule parameters needs to be set, if not the build fails.
Signed-off-by: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
Signed-off-by: Jon Mason <jon.mason@arm.com>
---
meta-arm/classes/uefi_capsule.bbclass | 46 +++++++++++++++++++++++++++
1 file changed, 46 insertions(+)
create mode 100644 meta-arm/classes/uefi_capsule.bbclass
diff --git a/meta-arm/classes/uefi_capsule.bbclass b/meta-arm/classes/uefi_capsule.bbclass
new file mode 100644
index 00000000..0c3d3845
--- /dev/null
+++ b/meta-arm/classes/uefi_capsule.bbclass
@@ -0,0 +1,46 @@
+# This class generates UEFI capsules
+# The current class supports generating a capsule with single firmware binary
+
+inherit python3native
+
+IMAGE_TYPES += "uefi_capsule"
+
+# edk2 base tools should be installed in the native sysroot directory
+do_image_uefi_capsule[depends] += "edk2-basetools-native:do_populate_sysroot"
+
+# By default the wic image is used to create a capsule
+CAPSULE_IMGTYPE ?= "wic"
+
+# IMGDEPLOYDIR is used as the default location of firmware binary for which the capsule needs to be created
+CAPSULE_IMGLOCATION ?= "${IMGDEPLOYDIR}"
+
+# The generated capsule by default has uefi.capsule extension
+CAPSULE_EXTENSION ?= "uefi.capsule"
+
+# The following variables must be set to be able to generate a capsule update
+UEFI_FIRMWARE_BINARY ?= ""
+UEFI_FIRMWARE_VERSION ?= ""
+UEFI_FIRMWARE_LSV ?= ""
+UEFI_FIRMWARE_GUID ?= ""
+UEFI_FIRMWARE_UPDATE_INDEX ?= ""
+
+# Check if the required variables are set
+python() {
+ for var in ["UEFI_FIRMWARE_BINARY", "UEFI_FIRMWARE_VERSION", "UEFI_FIRMWARE_LSV", "UEFI_FIRMWARE_GUID", "UEFI_FIRMWARE_UPDATE_INDEX"]:
+ if not d.getVar(var):
+ raise bb.parse.SkipRecipe(f"{var} not set")
+}
+
+IMAGE_CMD:uefi_capsule(){
+
+ # Force the GenerateCapsule script to use python3
+ export PYTHON_COMMAND=${PYTHON}
+
+ ${STAGING_DIR_NATIVE}/usr/bin/edk2-BaseTools/BinWrappers/PosixLike/GenerateCapsule -e -o \
+ ${CAPSULE_IMGLOCATION}/${UEFI_FIRMWARE_BINARY}.${CAPSULE_EXTENSION} --fw-version ${UEFI_FIRMWARE_VERSION} \
+ --lsv ${UEFI_FIRMWARE_LSV} --guid ${UEFI_FIRMWARE_GUID} --verbose --update-image-index \
+ ${UEFI_FIRMWARE_UPDATE_INDEX} --verbose ${CAPSULE_IMGLOCATION}/${UEFI_FIRMWARE_BINARY}
+}
+
+# The firmware binary should be created before generating the capsule
+IMAGE_TYPEDEP:uefi_capsule:append = "${CAPSULE_IMGTYPE}"
--
2.17.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [PATCH langdale 3/6] arm-bsp/corstone1000-image: Generate UEFI capsule for corstone1000 platform
2023-02-28 14:41 [PATCH langdale 0/6] Add UEFI capsule generation support gowtham.sureshkumar
2023-02-28 14:41 ` [PATCH langdale 1/6] arm/edk2-basetools: Add edk2 base tool native recipe gowtham.sureshkumar
2023-02-28 14:41 ` [PATCH langdale 2/6] arm-bsp/uefi_capsule: Add UEFI capsule generation class gowtham.sureshkumar
@ 2023-02-28 14:41 ` gowtham.sureshkumar
2023-02-28 14:41 ` [PATCH langdale 4/6] arm/edk2-basetools: Convert edk2 basetools recipes to native only gowtham.sureshkumar
` (3 subsequent siblings)
6 siblings, 0 replies; 8+ messages in thread
From: gowtham.sureshkumar @ 2023-02-28 14:41 UTC (permalink / raw)
To: meta-arm, Ross.Burton; +Cc: nd, Gowtham Suresh Kumar, Jon Mason
From: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
Inherits the UEFI capsule generation class and configures the capsule
variables for the wic.nopt image
Signed-off-by: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
Signed-off-by: Jon Mason <jon.mason@arm.com>
---
meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb | 9 ++++++++-
1 file changed, 8 insertions(+), 1 deletion(-)
diff --git a/meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb b/meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb
index 76a7126b..b0a71bca 100644
--- a/meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb
+++ b/meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb
@@ -7,10 +7,17 @@ COMPATIBLE_MACHINE = "corstone1000"
inherit image
inherit wic_nopt tfm_sign_image
+inherit uefi_capsule
PACKAGE_INSTALL = ""
-IMAGE_FSTYPES += "wic wic.nopt"
+IMAGE_FSTYPES += "wic wic.nopt uefi_capsule"
+
+UEFI_FIRMWARE_BINARY = "corstone1000-image-${MACHINE}.wic.nopt"
+UEFI_FIRMWARE_VERSION = "5"
+UEFI_FIRMWARE_LSV = "0"
+UEFI_FIRMWARE_GUID = "e2bb9c06-70e9-4b14-97a3-5a7913176e3f"
+UEFI_FIRMWARE_UPDATE_INDEX = "0"
do_sign_images() {
# Sign TF-A BL2
--
2.17.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [PATCH langdale 4/6] arm/edk2-basetools: Convert edk2 basetools recipes to native only
2023-02-28 14:41 [PATCH langdale 0/6] Add UEFI capsule generation support gowtham.sureshkumar
` (2 preceding siblings ...)
2023-02-28 14:41 ` [PATCH langdale 3/6] arm-bsp/corstone1000-image: Generate UEFI capsule for corstone1000 platform gowtham.sureshkumar
@ 2023-02-28 14:41 ` gowtham.sureshkumar
2023-02-28 14:41 ` [PATCH langdale 5/6] arm-bsp/uefi_capsule: Use json file to pass capsule config gowtham.sureshkumar
` (2 subsequent siblings)
6 siblings, 0 replies; 8+ messages in thread
From: gowtham.sureshkumar @ 2023-02-28 14:41 UTC (permalink / raw)
To: meta-arm, Ross.Burton; +Cc: nd, Gowtham Suresh Kumar, Jon Mason
From: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
The BBCLASSEXTEND configuration can generate native sdk and target
recipes as well. The cp command used in do_install will
create host contamination issues for these recipes, so this patch
makes the recipe native only.
Signed-off-by: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
Signed-off-by: Jon Mason <jon.mason@arm.com>
---
...-basetools_202211.bb => edk2-basetools-native_202211.bb} | 6 +++---
1 file changed, 3 insertions(+), 3 deletions(-)
rename meta-arm/recipes-devtools/edk2-basetools/{edk2-basetools_202211.bb => edk2-basetools-native_202211.bb} (92%)
diff --git a/meta-arm/recipes-devtools/edk2-basetools/edk2-basetools_202211.bb b/meta-arm/recipes-devtools/edk2-basetools/edk2-basetools-native_202211.bb
similarity index 92%
rename from meta-arm/recipes-devtools/edk2-basetools/edk2-basetools_202211.bb
rename to meta-arm/recipes-devtools/edk2-basetools/edk2-basetools-native_202211.bb
index c80fdae2..6a59c22c 100644
--- a/meta-arm/recipes-devtools/edk2-basetools/edk2-basetools_202211.bb
+++ b/meta-arm/recipes-devtools/edk2-basetools/edk2-basetools-native_202211.bb
@@ -3,7 +3,7 @@
# generating UEFI capsules as it only depends on some python scripts. Other
# tools need to be built first before adding to sysroot.
-DESCRIPTION = "EDK2 Base Tools"
+SUMMARY = "EDK2 Base Tools"
LICENSE = "BSD-2-Clause-Patent"
# EDK2
@@ -14,11 +14,11 @@ SRCREV = "fff6d81270b57ee786ea18ad74f43149b9f03494"
S = "${WORKDIR}/git"
+inherit native
+
RDEPENDS:${PN} += "python3-core"
do_install () {
mkdir -p ${D}${bindir}/edk2-BaseTools
cp -r ${WORKDIR}/git/BaseTools/* ${D}${bindir}/edk2-BaseTools/
}
-
-BBCLASSEXTEND = "native"
--
2.17.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [PATCH langdale 5/6] arm-bsp/uefi_capsule: Use json file to pass capsule config
2023-02-28 14:41 [PATCH langdale 0/6] Add UEFI capsule generation support gowtham.sureshkumar
` (3 preceding siblings ...)
2023-02-28 14:41 ` [PATCH langdale 4/6] arm/edk2-basetools: Convert edk2 basetools recipes to native only gowtham.sureshkumar
@ 2023-02-28 14:41 ` gowtham.sureshkumar
2023-02-28 14:41 ` [PATCH langdale 6/6] arm-bsp/uefi_capsule: Move UEFI capsule to IMGDEPLOYDIR gowtham.sureshkumar
2023-03-04 16:59 ` [PATCH langdale 0/6] Add UEFI capsule generation support Jon Mason
6 siblings, 0 replies; 8+ messages in thread
From: gowtham.sureshkumar @ 2023-02-28 14:41 UTC (permalink / raw)
To: meta-arm, Ross.Burton; +Cc: nd, Gowtham Suresh Kumar, Jon Mason
From: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
This patch uses the json config file for UEFI capsule generation
as this is efficient and easily scalable to generate multiple
capsules.
Signed-off-by: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
Signed-off-by: Jon Mason <jon.mason@arm.com>
---
.../recipes-bsp/images/corstone1000-image.bb | 8 +++---
...rstone1000-image-capsule-update-image.json | 11 ++++++++
meta-arm/classes/uefi_capsule.bbclass | 27 ++++++++++++-------
3 files changed, 32 insertions(+), 14 deletions(-)
create mode 100644 meta-arm-bsp/recipes-bsp/images/files/corstone1000-image-capsule-update-image.json
diff --git a/meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb b/meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb
index b0a71bca..932b1619 100644
--- a/meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb
+++ b/meta-arm-bsp/recipes-bsp/images/corstone1000-image.bb
@@ -13,11 +13,9 @@ PACKAGE_INSTALL = ""
IMAGE_FSTYPES += "wic wic.nopt uefi_capsule"
-UEFI_FIRMWARE_BINARY = "corstone1000-image-${MACHINE}.wic.nopt"
-UEFI_FIRMWARE_VERSION = "5"
-UEFI_FIRMWARE_LSV = "0"
-UEFI_FIRMWARE_GUID = "e2bb9c06-70e9-4b14-97a3-5a7913176e3f"
-UEFI_FIRMWARE_UPDATE_INDEX = "0"
+UEFI_FIRMWARE_BINARY = "${PN}-${MACHINE}.${CAPSULE_IMGTYPE}"
+UEFI_CAPSULE_CONFIG = "${THISDIR}/files/${PN}-capsule-update-image.json"
+CAPSULE_IMGTYPE = "wic.nopt"
do_sign_images() {
# Sign TF-A BL2
diff --git a/meta-arm-bsp/recipes-bsp/images/files/corstone1000-image-capsule-update-image.json b/meta-arm-bsp/recipes-bsp/images/files/corstone1000-image-capsule-update-image.json
new file mode 100644
index 00000000..0f011ff7
--- /dev/null
+++ b/meta-arm-bsp/recipes-bsp/images/files/corstone1000-image-capsule-update-image.json
@@ -0,0 +1,11 @@
+{
+ "Payloads": [
+ {
+ "FwVersion": "5",
+ "Guid": "e2bb9c06-70e9-4b14-97a3-5a7913176e3f",
+ "LowestSupportedVersion": "1",
+ "Payload": "$UEFI_FIRMWARE_BINARY",
+ "UpdateImageIndex": "0"
+ }
+ ]
+}
diff --git a/meta-arm/classes/uefi_capsule.bbclass b/meta-arm/classes/uefi_capsule.bbclass
index 0c3d3845..cf708412 100644
--- a/meta-arm/classes/uefi_capsule.bbclass
+++ b/meta-arm/classes/uefi_capsule.bbclass
@@ -1,6 +1,7 @@
# This class generates UEFI capsules
# The current class supports generating a capsule with single firmware binary
+DEPENDS += "gettext-native"
inherit python3native
IMAGE_TYPES += "uefi_capsule"
@@ -19,14 +20,11 @@ CAPSULE_EXTENSION ?= "uefi.capsule"
# The following variables must be set to be able to generate a capsule update
UEFI_FIRMWARE_BINARY ?= ""
-UEFI_FIRMWARE_VERSION ?= ""
-UEFI_FIRMWARE_LSV ?= ""
-UEFI_FIRMWARE_GUID ?= ""
-UEFI_FIRMWARE_UPDATE_INDEX ?= ""
+UEFI_CAPSULE_CONFIG ?= ""
# Check if the required variables are set
python() {
- for var in ["UEFI_FIRMWARE_BINARY", "UEFI_FIRMWARE_VERSION", "UEFI_FIRMWARE_LSV", "UEFI_FIRMWARE_GUID", "UEFI_FIRMWARE_UPDATE_INDEX"]:
+ for var in ["UEFI_FIRMWARE_BINARY", "UEFI_CAPSULE_CONFIG"]:
if not d.getVar(var):
raise bb.parse.SkipRecipe(f"{var} not set")
}
@@ -36,10 +34,21 @@ IMAGE_CMD:uefi_capsule(){
# Force the GenerateCapsule script to use python3
export PYTHON_COMMAND=${PYTHON}
- ${STAGING_DIR_NATIVE}/usr/bin/edk2-BaseTools/BinWrappers/PosixLike/GenerateCapsule -e -o \
- ${CAPSULE_IMGLOCATION}/${UEFI_FIRMWARE_BINARY}.${CAPSULE_EXTENSION} --fw-version ${UEFI_FIRMWARE_VERSION} \
- --lsv ${UEFI_FIRMWARE_LSV} --guid ${UEFI_FIRMWARE_GUID} --verbose --update-image-index \
- ${UEFI_FIRMWARE_UPDATE_INDEX} --verbose ${CAPSULE_IMGLOCATION}/${UEFI_FIRMWARE_BINARY}
+ # Copy the firmware and the capsule config json to current directory
+ if [ -e ${CAPSULE_IMGLOCATION}/${UEFI_FIRMWARE_BINARY} ]; then
+ cp ${CAPSULE_IMGLOCATION}/${UEFI_FIRMWARE_BINARY} . ;
+ fi
+
+ export UEFI_FIRMWARE_BINARY=${UEFI_FIRMWARE_BINARY}
+ envsubst < ${UEFI_CAPSULE_CONFIG} > ./${MACHINE}-capsule-update-image.json
+
+ ${STAGING_DIR_NATIVE}/usr/bin/edk2-BaseTools/BinWrappers/PosixLike/GenerateCapsule \
+ -e -o ${UEFI_FIRMWARE_BINARY}.${CAPSULE_EXTENSION} -j \
+ ${MACHINE}-capsule-update-image.json
+
+ # Remove the firmware to avoid contamination of IMGDEPLOYDIR
+ rm ${UEFI_FIRMWARE_BINARY}
+
}
# The firmware binary should be created before generating the capsule
--
2.17.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* [PATCH langdale 6/6] arm-bsp/uefi_capsule: Move UEFI capsule to IMGDEPLOYDIR
2023-02-28 14:41 [PATCH langdale 0/6] Add UEFI capsule generation support gowtham.sureshkumar
` (4 preceding siblings ...)
2023-02-28 14:41 ` [PATCH langdale 5/6] arm-bsp/uefi_capsule: Use json file to pass capsule config gowtham.sureshkumar
@ 2023-02-28 14:41 ` gowtham.sureshkumar
2023-03-04 16:59 ` [PATCH langdale 0/6] Add UEFI capsule generation support Jon Mason
6 siblings, 0 replies; 8+ messages in thread
From: gowtham.sureshkumar @ 2023-02-28 14:41 UTC (permalink / raw)
To: meta-arm, Ross.Burton; +Cc: nd, Gowtham Suresh Kumar
From: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
The UEFI capsule generated is in the incorrect build directory.
This patch copies it to IMGDEPLOYDIR.
Signed-off-by: Gowtham Suresh Kumar <gowtham.sureshkumar@arm.com>
---
meta-arm/classes/uefi_capsule.bbclass | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/meta-arm/classes/uefi_capsule.bbclass b/meta-arm/classes/uefi_capsule.bbclass
index cf708412..690e7af4 100644
--- a/meta-arm/classes/uefi_capsule.bbclass
+++ b/meta-arm/classes/uefi_capsule.bbclass
@@ -43,7 +43,7 @@ IMAGE_CMD:uefi_capsule(){
envsubst < ${UEFI_CAPSULE_CONFIG} > ./${MACHINE}-capsule-update-image.json
${STAGING_DIR_NATIVE}/usr/bin/edk2-BaseTools/BinWrappers/PosixLike/GenerateCapsule \
- -e -o ${UEFI_FIRMWARE_BINARY}.${CAPSULE_EXTENSION} -j \
+ -e -o ${IMGDEPLOYDIR}/${UEFI_FIRMWARE_BINARY}.${CAPSULE_EXTENSION} -j \
${MACHINE}-capsule-update-image.json
# Remove the firmware to avoid contamination of IMGDEPLOYDIR
--
2.17.1
^ permalink raw reply related [flat|nested] 8+ messages in thread
* Re: [PATCH langdale 0/6] Add UEFI capsule generation support
2023-02-28 14:41 [PATCH langdale 0/6] Add UEFI capsule generation support gowtham.sureshkumar
` (5 preceding siblings ...)
2023-02-28 14:41 ` [PATCH langdale 6/6] arm-bsp/uefi_capsule: Move UEFI capsule to IMGDEPLOYDIR gowtham.sureshkumar
@ 2023-03-04 16:59 ` Jon Mason
6 siblings, 0 replies; 8+ messages in thread
From: Jon Mason @ 2023-03-04 16:59 UTC (permalink / raw)
To: meta-arm, gowtham.sureshkumar, Ross.Burton; +Cc: nd
On Tue, 28 Feb 2023 14:41:46 +0000, gowtham.sureshkumar@arm.com wrote:
> The following patches adds a class for UEFI capsule generation,
> a recipe for installing edk2 base tools in the sysroot and
> configures the corstone1000 recipe to build a UEFI capsule.
>
> Gowtham Suresh Kumar (6):
> arm/edk2-basetools: Add edk2 base tool native recipe
> arm-bsp/uefi_capsule: Add UEFI capsule generation class
> arm-bsp/corstone1000-image: Generate UEFI capsule for corstone1000
> platform
> arm/edk2-basetools: Convert edk2 basetools recipes to native only
> arm-bsp/uefi_capsule: Use json file to pass capsule config
> arm-bsp/uefi_capsule: Move UEFI capsule to IMGDEPLOYDIR
>
> [...]
Applied, thanks!
[1/6] arm/edk2-basetools: Add edk2 base tool native recipe
commit: ccf216ce4d5e149d907ab2777b2b39d71b90bd53
[2/6] arm-bsp/uefi_capsule: Add UEFI capsule generation class
commit: 7a1649137389bff0ad1a4825a2dc148290437a3b
[3/6] arm-bsp/corstone1000-image: Generate UEFI capsule for corstone1000 platform
commit: 2792359e0a6d2663b0d8b523e2290b14029cc4fb
[4/6] arm/edk2-basetools: Convert edk2 basetools recipes to native only
commit: 50c462da2d60145b5dc65cfb54fe9020c6859774
[5/6] arm-bsp/uefi_capsule: Use json file to pass capsule config
commit: 71f92f4df8b8ea1a45bc8639fa2ced576d991ffc
[6/6] arm-bsp/uefi_capsule: Move UEFI capsule to IMGDEPLOYDIR
commit: 04071ec9f5091ec76da202ce610e256d8d347a60
Best regards,
--
Jon Mason <jon.mason@arm.com>
^ permalink raw reply [flat|nested] 8+ messages in thread