[PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Dmitry Eremin-Solenikov]

As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
separate task from do_deploy. This way the do_install task can also
benefit from generated uImage.

The only major feature of oe-core's version (not to recreate uImage
if it exists) is retained in this patch. On the contra, as this version
was merged from meta-oe/org.oe.dev, new function has another feature:
it permits overriding the u-boot entrypoint via u-boot symbol.

Signed-off-by: Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
---
 meta/classes/kernel.bbclass |   43 +++++++++++++++++++++++++++----------------
 1 files changed, 27 insertions(+), 16 deletions(-)

diff --git a/meta/classes/kernel.bbclass b/meta/classes/kernel.bbclass
index 3f2f75a..8832a77 100644
--- a/meta/classes/kernel.bbclass
+++ b/meta/classes/kernel.bbclass
@@ -489,6 +489,33 @@ do_sizecheck() {
 
 addtask sizecheck before do_install after do_compile
 
+# Define to 1 to force kernel.bbclass to recreate uImage for you
+KERNEL_RECREATE_UIMAGE ?= "0"
+
+do_uboot_mkimage() {
+    test "x${KERNEL_IMAGETYPE}" = "xuImage" || return 0
+    test "x${KERNEL_RECREATE_UIMAGE}" = "x1" -o ! -e arch/${ARCH}/boot/uImage || return 0
+
+    ENTRYPOINT=${UBOOT_ENTRYPOINT}
+    if test -n "${UBOOT_ENTRYSYMBOL}"; then
+        ENTRYPOINT=`${HOST_PREFIX}nm ${S}/vmlinux | \
+               awk '$3=="${UBOOT_ENTRYSYMBOL}" {print $1}'`
+    fi
+    if test -e arch/${ARCH}/boot/compressed/vmlinux ; then
+        ${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
+        uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C none -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin arch/${ARCH}/boot/uImage
+        rm -f linux.bin
+    else
+        ${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
+        rm -f linux.bin.gz
+        gzip -9 linux.bin
+        uboot-mkimage -A ${UBOOT_ARCH} -O linux -T kernel -C gzip -a ${UBOOT_LOADADDRESS} -e $ENTRYPOINT -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz arch/${ARCH}/boot/uImage
+        rm -f linux.bin.gz
+    fi
+}
+
+addtask uboot_mkimage before do_install after do_compile
+
 KERNEL_IMAGE_BASE_NAME ?= "${KERNEL_IMAGETYPE}-${PV}-${PR}-${MACHINE}-${DATETIME}"
 # Don't include the DATETIME variable in the sstate package signatures
 KERNEL_IMAGE_BASE_NAME[vardepsexclude] = "DATETIME"
@@ -500,22 +527,6 @@ kernel_do_deploy() {
 		tar -cvzf ${DEPLOYDIR}/modules-${KERNEL_VERSION}-${PR}-${MACHINE}.tgz -C ${D} lib
 	fi
 
-	if test "x${KERNEL_IMAGETYPE}" = "xuImage" ; then 
-		if test -e arch/${ARCH}/boot/uImage ; then
-			cp arch/${ARCH}/boot/uImage ${DEPLOYDIR}/${KERNEL_IMAGE_BASE_NAME}.bin
-		elif test -e arch/${ARCH}/boot/compressed/vmlinux ; then
-			${OBJCOPY} -O binary -R .note -R .comment -S arch/${ARCH}/boot/compressed/vmlinux linux.bin
-			uboot-mkimage -A ${ARCH} -O linux -T kernel -C none -a ${UBOOT_ENTRYPOINT} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin ${DEPLOYDIR}/${KERNEL_IMAGE_BASE_NAME}.bin
-			rm -f linux.bin
-		else
-			${OBJCOPY} -O binary -R .note -R .comment -S vmlinux linux.bin
-			rm -f linux.bin.gz
-			gzip -9 linux.bin
-			uboot-mkimage -A ${ARCH} -O linux -T kernel -C gzip -a ${UBOOT_ENTRYPOINT} -e ${UBOOT_ENTRYPOINT} -n "${DISTRO_NAME}/${PV}/${MACHINE}" -d linux.bin.gz ${DEPLOYDIR}/${KERNEL_IMAGE_BASE_NAME}.bin
-			rm -f linux.bin.gz
-		fi
-	fi
-
 	cd ${DEPLOYDIR}
 	rm -f ${KERNEL_IMAGE_SYMLINK_NAME}.bin
 	ln -sf ${KERNEL_IMAGE_BASE_NAME}.bin ${KERNEL_IMAGE_SYMLINK_NAME}.bin
-- 
1.7.7.3

[PATCH 2/5] Move check that all installed files are shipped into insane.bbclass

[Dmitry Eremin-Solenikov]

Checking that all installed files are shipped is in reality a QA check.
It would benefit from mechanisms like ERROR_QA/WARNING_QA. So move it
into insane.bbclass. If some of the files are installed but should not
be shipped for some reasons, one can add them to the variable
IGNORE_UNSHIPPED_FILES.

Signed-off-by: Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
---
 meta/classes/insane.bbclass  |   50 ++++++++++++++++++++++++++++++++++++++++-
 meta/classes/package.bbclass |   15 ------------
 2 files changed, 48 insertions(+), 17 deletions(-)

diff --git a/meta/classes/insane.bbclass b/meta/classes/insane.bbclass
index 5726e69..41b815c 100644
--- a/meta/classes/insane.bbclass
+++ b/meta/classes/insane.bbclass
@@ -100,7 +100,7 @@ def package_qa_get_machine_dict():
 
 
 # Currently not being used by default "desktop"
-WARN_QA ?= "ldflags useless-rpaths rpaths"
+WARN_QA ?= "ldflags useless-rpaths rpaths unshipped"
 ERROR_QA ?= "dev-so debug-deps dev-deps debug-files arch la2 pkgconfig la perms"
 
 def package_qa_clean_path(path,d):
@@ -485,6 +485,49 @@ def package_qa_check_rdepends(pkg, pkgdest, skip, d):
 
     return sane
 
+IGNORE_UNSHIPPED_FILES ??= ""
+
+def packages_qa_unshipped_files(d):
+    warn = (d.getVar('WARN_QA', True) or "").split()
+    err = (d.getVar('ERROR_QA', True) or "").split()
+    if not "unshipped" in warn + err:
+        return True
+
+    seen = d.getVar('IGNORE_UNSHIPPED_FILES', True).split()
+    unshipped = []
+    dvar = d.getVar('PKGD', True)
+    destvar = d.getVar('PKGDEST', True)
+    packages = d.getVar('PACKAGES', True).split()
+    for p in packages:
+        pdir = os.path.join(destvar, p)
+        for root, dirs, files in os.walk(pdir):
+            dir = root[len(pdir):]
+            if not dir:
+                dir = os.sep
+            for f in (files + dirs):
+                path = os.path.join(dir, f)
+                if path not in seen:
+                    seen.append(path)
+
+    for root, dirs, files in os.walk(dvar):
+        dir = root[len(dvar):]
+        if not dir:
+            dir = os.sep
+        for f in (files + dirs):
+            path = os.path.join(dir, f)
+            if path not in seen:
+                unshipped.append(path)
+
+    pn = d.getVar('PN', True)
+
+    if unshipped == []:
+        return True
+
+    ret = package_qa_handle_error("unshipped", "For recipe %s, the following files/directories were installed but not shipped in any package:" % pn, d)
+    for f in unshipped:
+        package_qa_handle_error("unshipped", f, d)
+    return ret
+
 # The PACKAGE FUNC to scan each package
 python do_package_qa () {
     bb.note("DO PACKAGE QA")
@@ -522,6 +565,7 @@ python do_package_qa () {
     g = globals()
     walk_sane = True
     rdepends_sane = True
+    shipped_sane = True
     for package in packages.split():
         skip = (d.getVar('INSANE_SKIP_' + package, True) or "").split()
         if skip:
@@ -546,8 +590,10 @@ python do_package_qa () {
         if not package_qa_check_rdepends(package, pkgdest, skip, d):
             rdepends_sane = False
 
+    if not packages_qa_unshipped_files(d):
+        shipped_sane = False
 
-    if not walk_sane or not rdepends_sane:
+    if not walk_sane or not rdepends_sane or not shipped_sane:
         bb.fatal("QA run found fatal errors. Please consider fixing them.")
     bb.note("DONE with PACKAGE QA")
 }
diff --git a/meta/classes/package.bbclass b/meta/classes/package.bbclass
index 39c1d4b..fbea9c6 100644
--- a/meta/classes/package.bbclass
+++ b/meta/classes/package.bbclass
@@ -957,21 +957,6 @@ python populate_packages () {
 		del localdata
 	os.chdir(workdir)
 
-	unshipped = []
-	for root, dirs, files in os.walk(dvar):
-		dir = root[len(dvar):]
-		if not dir:
-			dir = os.sep
-		for f in (files + dirs):
-			path = os.path.join(dir, f)
-			if ('.' + path) not in seen:
-				unshipped.append(path)
-
-	if unshipped != []:
-		bb.warn("For recipe %s, the following files/directories were installed but not shipped in any package:" % pn)
-		for f in unshipped:
-			bb.warn("  " + f)
-
 	bb.build.exec_func("package_name_hook", d)
 
 	for pkg in package_list:
-- 
1.7.7.3

Re: [PATCH 2/5] Move check that all installed files are shipped into insane.bbclass

[Khem Raj]

[-- Attachment #1: Type: text/plain, Size: 5093 bytes --]

On Sunday, December 18, 2011, Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
wrote:
> Checking that all installed files are shipped is in reality a QA check.
> It would benefit from mechanisms like ERROR_QA/WARNING_QA. So move it
> into insane.bbclass. If some of the files are installed but should not
> be shipped for some reasons, one can add them to the variable
> IGNORE_UNSHIPPED_FILES.
>

This needs to be documented somewhere too and may be added to
sample.conf.extended

> Signed-off-by: Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
> ---
>  meta/classes/insane.bbclass  |   50
++++++++++++++++++++++++++++++++++++++++-
>  meta/classes/package.bbclass |   15 ------------
>  2 files changed, 48 insertions(+), 17 deletions(-)
>
> diff --git a/meta/classes/insane.bbclass b/meta/classes/insane.bbclass
> index 5726e69..41b815c 100644
> --- a/meta/classes/insane.bbclass
> +++ b/meta/classes/insane.bbclass
> @@ -100,7 +100,7 @@ def package_qa_get_machine_dict():
>
>
>  # Currently not being used by default "desktop"
> -WARN_QA ?= "ldflags useless-rpaths rpaths"
> +WARN_QA ?= "ldflags useless-rpaths rpaths unshipped"
>  ERROR_QA ?= "dev-so debug-deps dev-deps debug-files arch la2 pkgconfig
la perms"
>
>  def package_qa_clean_path(path,d):
> @@ -485,6 +485,49 @@ def package_qa_check_rdepends(pkg, pkgdest, skip, d):
>
>     return sane
>
> +IGNORE_UNSHIPPED_FILES ??= ""
> +
> +def packages_qa_unshipped_files(d):
> +    warn = (d.getVar('WARN_QA', True) or "").split()
> +    err = (d.getVar('ERROR_QA', True) or "").split()
> +    if not "unshipped" in warn + err:
> +        return True
> +
> +    seen = d.getVar('IGNORE_UNSHIPPED_FILES', True).split()
> +    unshipped = []
> +    dvar = d.getVar('PKGD', True)
> +    destvar = d.getVar('PKGDEST', True)
> +    packages = d.getVar('PACKAGES', True).split()
> +    for p in packages:
> +        pdir = os.path.join(destvar, p)
> +        for root, dirs, files in os.walk(pdir):
> +            dir = root[len(pdir):]
> +            if not dir:
> +                dir = os.sep
> +            for f in (files + dirs):
> +                path = os.path.join(dir, f)
> +                if path not in seen
> +                    seen.append(path)
> +
> +    for root, dirs, files in os.walk(dvar):
> +        dir = root[len(dvar):]
> +        if not dir:
> +            dir = os.sep
> +        for f in (files + dirs):
> +            path = os.path.join(dir, f)
> +            if path not in seen:
> +                unshipped.append(path)
> +
> +    pn = d.getVar('PN', True)
> +
> +    if unshipped == []:
> +        return True
> +
> +    ret = package_qa_handle_error("unshipped", "For recipe %s, the
following files/directories were installed but not shipped in any package:"
% pn, d)
> +    for f in unshipped:
> +        package_qa_handle_error("unshipped", f, d)
> +    return ret
> +
>  # The PACKAGE FUNC to scan each package
>  python do_package_qa () {
>     bb.note("DO PACKAGE QA")
> @@ -522,6 +565,7 @@ python do_package_qa () {
>     g = globals()
>     walk_sane = True
>     rdepends_sane = True
> +    shipped_sane = True
>     for package in packages.split():
>         skip = (d.getVar('INSANE_SKIP_' + package, True) or "").split()
>         if skip:
> @@ -546,8 +590,10 @@ python do_package_qa () {
>         if not package_qa_check_rdepends(package, pkgdest, skip, d):
>             rdepends_sane = False
>
> +    if not packages_qa_unshipped_files(d):
> +        shipped_sane = False
>
> -    if not walk_sane or not rdepends_sane:
> +    if not walk_sane or not rdepends_sane or not shipped_sane:
>         bb.fatal("QA run found fatal errors. Please consider fixing
them.")
>     bb.note("DONE with PACKAGE QA")
>  }
> diff --git a/meta/classes/package.bbclass b/meta/classes/package.bbclass
> index 39c1d4b..fbea9c6 100644
> --- a/meta/classes/package.bbclass
> +++ b/meta/classes/package.bbclass
> @@ -957,21 +957,6 @@ python populate_packages () {
>                del localdata
>        os.chdir(workdir)
>
> -       unshipped = []
> -       for root, dirs, files in os.walk(dvar):
> -               dir = root[len(dvar):]
> -               if not dir:
> -                       dir = os.sep
> -               for f in (files + dirs):
> -                       path = os.path.join(dir, f)
> -                       if ('.' + path) not in seen:
> -                               unshipped.append(path)
> -
> -       if unshipped != []:
> -               bb.warn("For recipe %s, the following files/directories
were installed but not shipped in any package:" % pn)
> -               for f in unshipped:
> -                       bb.warn("  " + f)
> -
>        bb.build.exec_func("package_name_hook", d)
>
>        for pkg in package_list:
> --
> 1.7.7.3
>
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core
>

[-- Attachment #2: Type: text/html, Size: 6615 bytes --]

Re: [PATCH 2/5] Move check that all installed files are shipped into insane.bbclass

[Richard Purdie]

On Sun, 2011-12-18 at 15:29 -0800, Khem Raj wrote:
> On Sunday, December 18, 2011, Dmitry Eremin-Solenikov
> <dbaryshkov@gmail.com> wrote:
> > Checking that all installed files are shipped is in reality a QA
> check.
> > It would benefit from mechanisms like ERROR_QA/WARNING_QA. So move
> it
> > into insane.bbclass. If some of the files are installed but should
> not
> > be shipped for some reasons, one can add them to the variable
> > IGNORE_UNSHIPPED_FILES.
> >
> This needs to be documented somewhere too and may be added to
> sample.conf.extended

This doesn't make sense for sample.conf.extended. We're talking about a
recipe specific configuration variable, not distro/machine/conf config
which is more appropriate there.

I'd suggest adding to documentation.conf and/or the various manuals.

Cheers,

Richard

Re: [PATCH 2/5] Move check that all installed files are shipped into insane.bbclass

[Khem Raj]

On Sun, Dec 18, 2011 at 4:02 PM, Richard Purdie
<richard.purdie@linuxfoundation.org> wrote:
> On Sun, 2011-12-18 at 15:29 -0800, Khem Raj wrote:
>> On Sunday, December 18, 2011, Dmitry Eremin-Solenikov
>> <dbaryshkov@gmail.com> wrote:
>> > Checking that all installed files are shipped is in reality a QA
>> check.
>> > It would benefit from mechanisms like ERROR_QA/WARNING_QA. So move
>> it
>> > into insane.bbclass. If some of the files are installed but should
>> not
>> > be shipped for some reasons, one can add them to the variable
>> > IGNORE_UNSHIPPED_FILES.
>> >
>> This needs to be documented somewhere too and may be added to
>> sample.conf.extended
>
> This doesn't make sense for sample.conf.extended. We're talking about a
> recipe specific configuration variable, not distro/machine/conf config
> which is more appropriate there.

yes forgot that

>
> I'd suggest adding to documentation.conf and/or the various manuals.
>
> Cheers,
>
> Richard
>
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core

[PATCH 3/5] ncurses: drop compatibility symlink to remove QA warning

[Dmitry Eremin-Solenikov]

ncurses doesn't use ${libdir}/terminfo. It is a backwards-compatibility
symlink to ${datadir}/terminfo. It is not installed by ncurses recipe.
Drop it to drop QA warning.

Signed-off-by: Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
---
 meta/recipes-core/ncurses/ncurses.inc |    2 ++
 1 files changed, 2 insertions(+), 0 deletions(-)

diff --git a/meta/recipes-core/ncurses/ncurses.inc b/meta/recipes-core/ncurses/ncurses.inc
index 98f45a4..1449f34 100644
--- a/meta/recipes-core/ncurses/ncurses.inc
+++ b/meta/recipes-core/ncurses/ncurses.inc
@@ -171,6 +171,8 @@ do_install() {
         echo 'INPUT(AS_NEEDED(-ltinfo))' >>$f
 
 	oe_multilib_header curses.h
+
+	rm ${D}${libdir}/terminfo
 }
 
 python populate_packages_prepend () {
-- 
1.7.7.3

[PATCH 4/5] libatomics-ops: move docs to correct directory

[Dmitry Eremin-Solenikov]

Signed-off-by: Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
---
 .../pulseaudio/libatomics-ops_1.2.bb               |    6 ++++--
 1 files changed, 4 insertions(+), 2 deletions(-)

diff --git a/meta/recipes-multimedia/pulseaudio/libatomics-ops_1.2.bb b/meta/recipes-multimedia/pulseaudio/libatomics-ops_1.2.bb
index 184c167..d0162e6 100644
--- a/meta/recipes-multimedia/pulseaudio/libatomics-ops_1.2.bb
+++ b/meta/recipes-multimedia/pulseaudio/libatomics-ops_1.2.bb
@@ -6,7 +6,7 @@ LICENSE = "GPLv2 & MIT"
 LIC_FILES_CHKSUM = "file://doc/COPYING;md5=94d55d512a9ba36caa9b7df079bae19f \
                     file://doc/LICENSING.txt;md5=607073e04548eac7d1f763e480477bab \
 		   "
-PR = "r8"
+PR = "r9"
 
 SRC_URI = "http://www.hpl.hp.com/research/linux/atomic_ops/download/libatomic_ops-${PV}.tar.gz \
            file://fedora/libatomic_ops-1.2-ppclwzfix.patch \
@@ -26,5 +26,7 @@ ARM_INSTRUCTION_SET = "arm"
 inherit autotools pkgconfig
 
 do_install_append() {
-	mv ${D}${datadir}/libatomic_ops ${D}${datadir}/libatomic-ops || true
+	# those contain only docs, not necessary for now.
+	install -m 0755 -d ${D}${docdir}
+	mv ${D}${datadir}/libatomic_ops ${D}${docdir}/${PN}
 }
-- 
1.7.7.3

Re: [PATCH 4/5] libatomics-ops: move docs to correct directory

[Richard Purdie]

On Sun, 2011-12-18 at 23:47 +0400, Dmitry Eremin-Solenikov wrote:
> Signed-off-by: Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
> ---
>  .../pulseaudio/libatomics-ops_1.2.bb               |    6 ++++--
>  1 files changed, 4 insertions(+), 2 deletions(-)

Merged to master, thanks.

Richard

[PATCH 5/5] icecc.bbclass: also use icecc for kernel modules compilation

[Dmitry Eremin-Solenikov]

Signed-off-by: Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
---
 meta/classes/icecc.bbclass |    4 ++++
 1 files changed, 4 insertions(+), 0 deletions(-)

diff --git a/meta/classes/icecc.bbclass b/meta/classes/icecc.bbclass
index 7e3676a..a14e02d 100644
--- a/meta/classes/icecc.bbclass
+++ b/meta/classes/icecc.bbclass
@@ -211,6 +211,10 @@ do_compile_prepend() {
     set_icecc_env
 }
 
+do_compile_kernelmodules_prepend() {
+    set_icecc_env
+}
+
 #do_install_prepend() {
 #    set_icecc_env
 #}
-- 
1.7.7.3

Re: [PATCH 5/5] icecc.bbclass: also use icecc for kernel modules compilation

[Richard Purdie]

On Sun, 2011-12-18 at 23:47 +0400, Dmitry Eremin-Solenikov wrote:
> Signed-off-by: Dmitry Eremin-Solenikov <dbaryshkov@gmail.com>
> ---
>  meta/classes/icecc.bbclass |    4 ++++
>  1 files changed, 4 insertions(+), 0 deletions(-)

Merged to master, thanks.

Richard

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Koen Kooi]

[-- Attachment #1: Type: text/plain, Size: 767 bytes --]


Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:

> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
> separate task from do_deploy. This way the do_install task can also
> benefit from generated uImage.
> 
> The only major feature of oe-core's version (not to recreate uImage
> if it exists) is retained in this patch.

I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.

> On the contra, as this version
> was merged from meta-oe/org.oe.dev, new function has another feature:
> it permits overriding the u-boot entrypoint via u-boot symbol.

No it doesn't, since it doesn't recreate uImage.

[-- Attachment #2: Message signed with OpenPGP using GPGMail --]
[-- Type: application/pgp-signature, Size: 169 bytes --]

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Bruce Ashfield]

On Sun, Dec 18, 2011 at 3:13 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>
> Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>
>> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
>> separate task from do_deploy. This way the do_install task can also
>> benefit from generated uImage.
>>
>> The only major feature of oe-core's version (not to recreate uImage
>> if it exists) is retained in this patch.
>
> I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.

In that case, shouldn't people doing u-boot development (or other
non-kernel developers),
be building a uImage via something that isn't in kernel.bbclass ?

Cheers,

Bruce

>
>> On the contra, as this version
>> was merged from meta-oe/org.oe.dev, new function has another feature:
>> it permits overriding the u-boot entrypoint via u-boot symbol.
>
> No it doesn't, since it doesn't recreate uImage.
> -----BEGIN PGP SIGNATURE-----
>
> iEYEARECAAYFAk7uSX8ACgkQMkyGM64RGpGCLwCgtXQaYv3fu3891FMVs9AK8hK7
> z8QAniVSDXosv3RBKp0GYUnqfCXck2bD
> =UYJG
> -----END PGP SIGNATURE-----
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core
>



-- 
"Thou shalt not follow the NULL pointer, for chaos and madness await
thee at its end"

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Koen Kooi]

[-- Attachment #1: Type: text/plain, Size: 958 bytes --]


Op 18 dec. 2011, om 21:27 heeft Bruce Ashfield het volgende geschreven:

> On Sun, Dec 18, 2011 at 3:13 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>> 
>> Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>> 
>>> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
>>> separate task from do_deploy. This way the do_install task can also
>>> benefit from generated uImage.
>>> 
>>> The only major feature of oe-core's version (not to recreate uImage
>>> if it exists) is retained in this patch.
>> 
>> I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.
> 
> In that case, shouldn't people doing u-boot development (or other
> non-kernel developers),
> be building a uImage via something that isn't in kernel.bbclass ?

I use the kernel.bbclass in meta-oe, that does what I need.

[-- Attachment #2: Message signed with OpenPGP using GPGMail --]
[-- Type: application/pgp-signature, Size: 169 bytes --]

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Bruce Ashfield]

On Sun, Dec 18, 2011 at 4:19 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>
> Op 18 dec. 2011, om 21:27 heeft Bruce Ashfield het volgende geschreven:
>
>> On Sun, Dec 18, 2011 at 3:13 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>>>
>>> Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>>>
>>>> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
>>>> separate task from do_deploy. This way the do_install task can also
>>>> benefit from generated uImage.
>>>>
>>>> The only major feature of oe-core's version (not to recreate uImage
>>>> if it exists) is retained in this patch.
>>>
>>> I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.
>>
>> In that case, shouldn't people doing u-boot development (or other
>> non-kernel developers),
>> be building a uImage via something that isn't in kernel.bbclass ?
>
> I use the kernel.bbclass in meta-oe, that does what I need.

ok. I was just trying to wrap my head around the use case, since I'm missing
something, and that would help me understand what is missing in the in kernel
uImage generation scripts. With that, we could see about getting
changes upstream
to address deficiencies.

Cheers,

Bruce

> -----BEGIN PGP SIGNATURE-----
>
> iEYEARECAAYFAk7uWPsACgkQMkyGM64RGpHe8ACdEdFi1Nh17keaiRxAAWQI3Rh6
> 2CYAoKcYow2t+pnGOlJs7teSNB4IQARn
> =3QuN
> -----END PGP SIGNATURE-----
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core
>



-- 
"Thou shalt not follow the NULL pointer, for chaos and madness await
thee at its end"

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Khem Raj]

On Sun, Dec 18, 2011 at 5:39 PM, Bruce Ashfield
<bruce.ashfield@gmail.com> wrote:
> On Sun, Dec 18, 2011 at 4:19 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>>
>> Op 18 dec. 2011, om 21:27 heeft Bruce Ashfield het volgende geschreven:
>>
>>> On Sun, Dec 18, 2011 at 3:13 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>>>>
>>>> Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>>>>
>>>>> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
>>>>> separate task from do_deploy. This way the do_install task can also
>>>>> benefit from generated uImage.
>>>>>
>>>>> The only major feature of oe-core's version (not to recreate uImage
>>>>> if it exists) is retained in this patch.
>>>>
>>>> I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.
>>>
>>> In that case, shouldn't people doing u-boot development (or other
>>> non-kernel developers),
>>> be building a uImage via something that isn't in kernel.bbclass ?
>>

i think we have UBOOT_ENTRYPOINT, UBOOT_ENTRYSYMBOL and
UBOOT_LOADADDRESS which are then used to generate the uImage
and sometimes defaults from kernel build system may not be usable as
it might be generating the image using some other values and we are not
able to control the image generation. Now is that fixable in kernel I guess
it could be but why not have flexibility of generating the image.

>> I use the kernel.bbclass in meta-oe, that does what I need.
>

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Bruce Ashfield]

On Mon, Dec 19, 2011 at 12:06 AM, Khem Raj <raj.khem@gmail.com> wrote:
> On Sun, Dec 18, 2011 at 5:39 PM, Bruce Ashfield
> <bruce.ashfield@gmail.com> wrote:
>> On Sun, Dec 18, 2011 at 4:19 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>>>
>>> Op 18 dec. 2011, om 21:27 heeft Bruce Ashfield het volgende geschreven:
>>>
>>>> On Sun, Dec 18, 2011 at 3:13 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>>>>>
>>>>> Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>>>>>
>>>>>> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
>>>>>> separate task from do_deploy. This way the do_install task can also
>>>>>> benefit from generated uImage.
>>>>>>
>>>>>> The only major feature of oe-core's version (not to recreate uImage
>>>>>> if it exists) is retained in this patch.
>>>>>
>>>>> I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.
>>>>
>>>> In that case, shouldn't people doing u-boot development (or other
>>>> non-kernel developers),
>>>> be building a uImage via something that isn't in kernel.bbclass ?
>>>
>
> i think we have UBOOT_ENTRYPOINT, UBOOT_ENTRYSYMBOL and
> UBOOT_LOADADDRESS which are then used to generate the uImage
> and sometimes defaults from kernel build system may not be usable as
> it might be generating the image using some other values and we are not
> able to control the image generation. Now is that fixable in kernel I guess
> it could be but why not have flexibility of generating the image.

I'm all for flexibility (see my comments earlier in the thread), have a variable
or some other construct that specifies how you'd like to construct the uImage
(kernel vs non-kernel, as a basic attempt to differentiate the two).

I'm just driving for the details to see if we can remedy the situation in the
medium to long term, since burying the details of how to construct any sort
of image in multiple places .. is not ideal (but I state the obvious).

Cheers,

Bruce

>
>>> I use the kernel.bbclass in meta-oe, that does what I need.
>>
>
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.linuxtogo.org/cgi-bin/mailman/listinfo/openembedded-core



-- 
"Thou shalt not follow the NULL pointer, for chaos and madness await
thee at its end"

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Koen Kooi]

[-- Attachment #1: Type: text/plain, Size: 1797 bytes --]


Op 19 dec. 2011, om 02:39 heeft Bruce Ashfield het volgende geschreven:

> On Sun, Dec 18, 2011 at 4:19 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>> 
>> Op 18 dec. 2011, om 21:27 heeft Bruce Ashfield het volgende geschreven:
>> 
>>> On Sun, Dec 18, 2011 at 3:13 PM, Koen Kooi <koen@dominion.thruhere.net> wrote:
>>>> 
>>>> Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>>>> 
>>>>> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
>>>>> separate task from do_deploy. This way the do_install task can also
>>>>> benefit from generated uImage.
>>>>> 
>>>>> The only major feature of oe-core's version (not to recreate uImage
>>>>> if it exists) is retained in this patch.
>>>> 
>>>> I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.
>>> 
>>> In that case, shouldn't people doing u-boot development (or other
>>> non-kernel developers),
>>> be building a uImage via something that isn't in kernel.bbclass ?
>> 
>> I use the kernel.bbclass in meta-oe, that does what I need.
> 
> ok. I was just trying to wrap my head around the use case, since I'm missing
> something, and that would help me understand what is missing in the in kernel
> uImage generation scripts. With that, we could see about getting
> changes upstream
> to address deficiencies.


The biggest problem is that "upstream" is $vendor in a lot of cases, so fixing it once in OE is more productive than patching N vendor kernels. I agree that mainline should have the working version, but for my current project mainline doesn't even have support for this SoC and won't have till devicetree has cured worldpeace.

regards,

Koen

[-- Attachment #2: Message signed with OpenPGP using GPGMail --]
[-- Type: application/pgp-signature, Size: 169 bytes --]

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Dmitry Eremin-Solenikov]

On 12/19/2011 12:13 AM, Koen Kooi wrote:
>
> Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>
>> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
>> separate task from do_deploy. This way the do_install task can also
>> benefit from generated uImage.
>>
>> The only major feature of oe-core's version (not to recreate uImage
>> if it exists) is retained in this patch.
>
> I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.

Koen, that was addressed with KERNEL_RECREATE_UIMAGE variable.
Probably I should document it somewhere (in the commit message?
documentation.conf? smwh. else?). Would you agree with this patch + docs?

>
>> On the contra, as this version
>> was merged from meta-oe/org.oe.dev, new function has another feature:
>> it permits overriding the u-boot entrypoint via u-boot symbol.
>
> No it doesn't, since it doesn't recreate uImage.

It does.

BTW: I don't have much experience of uImage usage on ARM SoCs (I used
them only on Atmel boards, where things usually 'just worked' regarding 
Kernel load address & Ko). On PowerPC I also didn't have too much 
problems with upstream kernels (both from Linus'es tree and from 
Freescale's one).

I understand your concern, that for your tasks, you have to recreate 
uImage using your sane values. However for some people sane values are 
ones present in upstream tree. Moreover, if you care about history, it 
was specially changed in oe-core not to recreate uImage, as it caused 
problems for some of the users.

-- 
With best wishes
Dmitry

Re: [PATCH 1/5] kernel.bbclass: move uImage handling to separate task

[Dmitry Eremin-Solenikov]

On 12/19/2011 04:54 PM, Koen Kooi wrote:
>
> Op 19 dec. 2011, om 13:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>
>>
>>
>> On 12/19/2011 12:13 AM, Koen Kooi wrote:
>>>
>>> Op 18 dec. 2011, om 20:47 heeft Dmitry Eremin-Solenikov het volgende geschreven:
>>>
>>>> As per org.oe.dev and meta-oe's kernel.bbclass move uImage creation to
>>>> separate task from do_deploy. This way the do_install task can also
>>>> benefit from generated uImage.
>>>>
>>>> The only major feature of oe-core's version (not to recreate uImage
>>>> if it exists) is retained in this patch.
>>>
>>> I still don't agree with that behaviour. The in-kernel uImage code is just like the in-kernel defconfigs: useless for people who aren't kernel developers.
>>
>> Koen, that was addressed with KERNEL_RECREATE_UIMAGE variable.
>> Probably I should document it somewhere (in the commit message?
>> documentation.conf? smwh. else?). Would you agree with this patch + docs?
>
> No. If the machine.conf sets the UBOOT_* variables I should not need some magic unbreak-me variable to get kernel.bbclass to use them.

I see your point. I'll redo it so.

-- 
With best wishes
Dmitry