[PATCH 1/3] libidn2: add new version

[PATCH 1/3] libidn2: add new version

[Ross Burton]

libidn 1.x is deprecated, add the parallel-installable libidn2.

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 meta/recipes-extended/libidn/libidn2_2.0.5.bb | 23 +++++++++++++++++++++++
 1 file changed, 23 insertions(+)
 create mode 100644 meta/recipes-extended/libidn/libidn2_2.0.5.bb

diff --git a/meta/recipes-extended/libidn/libidn2_2.0.5.bb b/meta/recipes-extended/libidn/libidn2_2.0.5.bb
new file mode 100644
index 00000000000..aaf9ecd7e78
--- /dev/null
+++ b/meta/recipes-extended/libidn/libidn2_2.0.5.bb
@@ -0,0 +1,23 @@
+SUMMARY = "Internationalized Domain Name support library"
+DESCRIPTION = "Implementation of the Stringprep, Punycode and IDNA specifications defined by the IETF Internationalized Domain Names (IDN) working group."
+HOMEPAGE = "http://www.gnu.org/software/libidn/"
+SECTION = "libs"
+LICENSE = "(GPLv2+ | LGPLv3) & GPLv3+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=ab90e75ef97cc6318ce4f2fbda62fe4d \
+                    file://COPYING.LESSERv3;md5=e6a600fd5e1d9cbde2d983680233ad02 \
+                    file://COPYINGv2;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+                    file://src/idn2.c;endline=16;md5=0283aec28e049f5bcaaeee52aa865874 \
+                    file://lib/idn2.h.in;endline=27;md5=c2cd28d3f87260f157f022eabb83714f"
+
+SRC_URI = "${GNU_MIRROR}/libidn/${BPN}-${PV}.tar.gz"
+SRC_URI[md5sum] = "eaf9a5b9d03b0cce3760f34b3124eb36"
+SRC_URI[sha256sum] = "53f69170886f1fa6fa5b332439c7a77a7d22626a82ef17e2c1224858bb4ca2b8"
+
+DEPENDS = "virtual/libiconv libunistring"
+
+inherit pkgconfig autotools gettext texinfo gtk-doc lib_package
+
+LICENSE_${PN} = "(GPLv2+ | LGPLv3)"
+LICENSE_${PN}-bin = "GPLv3+"
+
+BBCLASSEXTEND = "native nativesdk"
-- 
2.11.0

[PATCH 2/3] gnutls: rationalise libunistring arguments

[Ross Burton]

No need to pass --without-libunistring-prefix, and it looks a lot like we're
trying to disable it.

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 meta/recipes-support/gnutls/gnutls.inc | 1 -
 1 file changed, 1 deletion(-)

diff --git a/meta/recipes-support/gnutls/gnutls.inc b/meta/recipes-support/gnutls/gnutls.inc
index 98ec8d9667b..b62a137e595 100644
--- a/meta/recipes-support/gnutls/gnutls.inc
+++ b/meta/recipes-support/gnutls/gnutls.inc
@@ -41,7 +41,6 @@ EXTRA_OECONF = " \
     --enable-local-libopts \
     --enable-openssl-compatibility \
     --with-libpthread-prefix=${STAGING_DIR_HOST}${prefix} \
-    --without-libunistring-prefix \
 "
 
 LDFLAGS_append_libc-musl = " -largp"
-- 
2.11.0

[PATCH 3/3] gnutls: fix libidn dependencies

[Ross Burton]

gnutls only works with libidn2, so update the build dependency.

Signed-off-by: Ross Burton <ross.burton@intel.com>
---
 meta/recipes-support/gnutls/gnutls.inc | 4 +---
 1 file changed, 1 insertion(+), 3 deletions(-)

diff --git a/meta/recipes-support/gnutls/gnutls.inc b/meta/recipes-support/gnutls/gnutls.inc
index b62a137e595..876a3847b0e 100644
--- a/meta/recipes-support/gnutls/gnutls.inc
+++ b/meta/recipes-support/gnutls/gnutls.inc
@@ -25,10 +25,8 @@ PACKAGECONFIG ??= "libidn"
 
 # You must also have CONFIG_SECCOMP enabled in the kernel for
 # seccomp to work.
-#
 PACKAGECONFIG[seccomp] = "ac_cv_libseccomp=yes,ac_cv_libseccomp=no,libseccomp"
-
-PACKAGECONFIG[libidn] = "--with-idn,--without-idn,libidn"
+PACKAGECONFIG[libidn] = "--with-idn,--without-idn,libidn2"
 PACKAGECONFIG[libtasn1] = "--with-included-libtasn1=no,--with-included-libtasn1,libtasn1"
 PACKAGECONFIG[p11-kit] = "--with-p11-kit,--without-p11-kit,p11-kit"
 PACKAGECONFIG[tpm] = "--with-tpm,--without-tpm,trousers"
-- 
2.11.0

Re: [PATCH 2/3] gnutls: rationalise libunistring arguments

[Khem Raj]

On Mon, Jul 23, 2018 at 4:51 AM Ross Burton <ross.burton@intel.com> wrote:
>
> No need to pass --without-libunistring-prefix, and it looks a lot like we're
> trying to disable it.
>

This sneaked in and I did not notice it in the series, but its going
to cause regression
on build machines who installed libunistring on host. Its also because
gnuts is using
non standard AC macro called AC_LIB_HAVE_LINKFLAGS to detect this
library and it seems to be confusing cross builds.

This commit is essentially reverting
http://git.openembedded.org/openembedded-core/commit/?id=ee0b0da237c1661f43e27e26e0ab24b7d8ed174f

which was added to fix the above case. This should be reverted.

> Signed-off-by: Ross Burton <ross.burton@intel.com>
> ---
>  meta/recipes-support/gnutls/gnutls.inc | 1 -
>  1 file changed, 1 deletion(-)
>
> diff --git a/meta/recipes-support/gnutls/gnutls.inc b/meta/recipes-support/gnutls/gnutls.inc
> index 98ec8d9667b..b62a137e595 100644
> --- a/meta/recipes-support/gnutls/gnutls.inc
> +++ b/meta/recipes-support/gnutls/gnutls.inc
> @@ -41,7 +41,6 @@ EXTRA_OECONF = " \
>      --enable-local-libopts \
>      --enable-openssl-compatibility \
>      --with-libpthread-prefix=${STAGING_DIR_HOST}${prefix} \
> -    --without-libunistring-prefix \
>  "
>
>  LDFLAGS_append_libc-musl = " -largp"
> --
> 2.11.0
>
> --
> _______________________________________________
> Openembedded-core mailing list
> Openembedded-core@lists.openembedded.org
> http://lists.openembedded.org/mailman/listinfo/openembedded-core