From: Marc Zyngier <maz@kernel.org>
To: linux-arm-kernel@lists.infradead.org, kvmarm@lists.cs.columbia.edu
Cc: kernel-team@android.com,
Catalin Marinas <catalin.marinas@arm.com>,
Will Deacon <will@kernel.org>, Ard Biesheuvel <ardb@kernel.org>
Subject: [PATCH 04/17] arm64: Provide an 'upgrade to VHE' stub hypercall
Date: Mon, 28 Dec 2020 10:49:45 +0000 [thread overview]
Message-ID: <20201228104958.1848833-5-maz@kernel.org> (raw)
In-Reply-To: <20201228104958.1848833-1-maz@kernel.org>
As we are about to change the way a VHE system boots, let's
provide the core helper, in the form of a stub hypercall that
enables VHE and replicates the full EL1 context at EL2, thanks
to EL1 and VHE-EL2 being extremely similar.
On exception return, the kernel carries on at EL2. Fancy!
Nothing calls this new hypercall yet, so no functional change.
Signed-off-by: Marc Zyngier <maz@kernel.org>
---
arch/arm64/include/asm/virt.h | 7 +++-
arch/arm64/kernel/hyp-stub.S | 70 ++++++++++++++++++++++++++++++++++-
2 files changed, 74 insertions(+), 3 deletions(-)
diff --git a/arch/arm64/include/asm/virt.h b/arch/arm64/include/asm/virt.h
index ee6a48df89d9..7379f35ae2c6 100644
--- a/arch/arm64/include/asm/virt.h
+++ b/arch/arm64/include/asm/virt.h
@@ -35,8 +35,13 @@
*/
#define HVC_RESET_VECTORS 2
+/*
+ * HVC_VHE_RESTART - Upgrade the CPU from EL1 to EL2, if possible
+ */
+#define HVC_VHE_RESTART 3
+
/* Max number of HYP stub hypercalls */
-#define HVC_STUB_HCALL_NR 3
+#define HVC_STUB_HCALL_NR 4
/* Error returned when an invalid stub number is passed into x0 */
#define HVC_STUB_ERR 0xbadca11
diff --git a/arch/arm64/kernel/hyp-stub.S b/arch/arm64/kernel/hyp-stub.S
index 160f5881a0b7..6ffdc1f7778b 100644
--- a/arch/arm64/kernel/hyp-stub.S
+++ b/arch/arm64/kernel/hyp-stub.S
@@ -8,9 +8,9 @@
#include <linux/init.h>
#include <linux/linkage.h>
-#include <linux/irqchip/arm-gic-v3.h>
#include <asm/assembler.h>
+#include <asm/el2_setup.h>
#include <asm/kvm_arm.h>
#include <asm/kvm_asm.h>
#include <asm/ptrace.h>
@@ -47,10 +47,16 @@ SYM_CODE_END(__hyp_stub_vectors)
SYM_CODE_START_LOCAL(el1_sync)
cmp x0, #HVC_SET_VECTORS
- b.ne 2f
+ b.ne 1f
msr vbar_el2, x1
b 9f
+1: cmp x0, #HVC_VHE_RESTART
+ b.ne 2f
+ mov x0, #HVC_SOFT_RESTART
+ adr x1, mutate_to_vhe
+ // fall through...
+
2: cmp x0, #HVC_SOFT_RESTART
b.ne 3f
mov x0, x2
@@ -70,6 +76,66 @@ SYM_CODE_START_LOCAL(el1_sync)
eret
SYM_CODE_END(el1_sync)
+// nVHE? No way! Give me the real thing!
+SYM_CODE_START_LOCAL(mutate_to_vhe)
+ // Sanity check: MMU *must* be off
+ mrs x0, sctlr_el2
+ tbnz x0, #0, 1f
+
+ // Needs to be VHE capable, obviously
+ mrs x0, id_aa64mmfr1_el1
+ ubfx x0, x0, #ID_AA64MMFR1_VHE_SHIFT, #4
+ cbz x0, 1f
+
+ // Engage the VHE magic!
+ mov_q x0, HCR_HOST_VHE_FLAGS
+ msr hcr_el2, x0
+ isb
+
+ // Doesn't do much on VHE, but still, worth a shot
+ init_el2_state vhe
+
+ // Use the EL1 allocated stack, per-cpu offset
+ mrs x0, sp_el1
+ mov sp, x0
+ mrs x0, tpidr_el1
+ msr tpidr_el2, x0
+
+ // FP configuration, vectors
+ mrs_s x0, SYS_CPACR_EL12
+ msr cpacr_el1, x0
+ mrs_s x0, SYS_VBAR_EL12
+ msr vbar_el1, x0
+
+ // Transfert the MM state from EL1 to EL2
+ mrs_s x0, SYS_TCR_EL12
+ msr tcr_el1, x0
+ mrs_s x0, SYS_TTBR0_EL12
+ msr ttbr0_el1, x0
+ mrs_s x0, SYS_TTBR1_EL12
+ msr ttbr1_el1, x0
+ mrs_s x0, SYS_MAIR_EL12
+ msr mair_el1, x0
+ isb
+
+ // Invalidate TLBs before enabling the MMU
+ tlbi vmalle1
+ dsb nsh
+
+ // Enable the EL2 S1 MMU, as set up from EL1
+ mrs_s x0, SYS_SCTLR_EL12
+ set_sctlr_el1 x0
+
+ // Hack the exception return to stay at EL2
+ mrs x0, spsr_el1
+ and x0, x0, #~PSR_MODE_MASK
+ mov x1, #PSR_MODE_EL2h
+ orr x0, x0, x1
+ msr spsr_el1, x0
+
+1: eret
+SYM_CODE_END(mutate_to_vhe)
+
.macro invalid_vector label
SYM_CODE_START_LOCAL(\label)
b \label
--
2.29.2
_______________________________________________
kvmarm mailing list
kvmarm@lists.cs.columbia.edu
https://lists.cs.columbia.edu/mailman/listinfo/kvmarm
next prev parent reply other threads:[~2020-12-28 10:50 UTC|newest]
Thread overview: 21+ messages / expand[flat|nested] mbox.gz Atom feed top
2020-12-28 10:49 [PATCH 00/17] arm64: Early CPU feature override, and an application to VHE Marc Zyngier
2020-12-28 10:49 ` [PATCH 01/17] arm64: Fix labels in el2_setup macros Marc Zyngier
2020-12-28 10:49 ` [PATCH 02/17] arm64: Fix outdated TCR setup comment Marc Zyngier
2020-12-28 10:49 ` [PATCH 03/17] arm64: Turn the MMU-on sequence into a macro Marc Zyngier
2020-12-28 10:49 ` Marc Zyngier [this message]
2021-01-04 23:39 ` [PATCH 04/17] arm64: Provide an 'upgrade to VHE' stub hypercall Jing Zhang
2021-01-05 8:24 ` Marc Zyngier
2020-12-28 10:49 ` [PATCH 05/17] arm64: Initialise as nVHE before switching to VHE Marc Zyngier
2020-12-28 10:49 ` [PATCH 06/17] arm64: Move VHE-specific SPE setup to mutate_to_vhe() Marc Zyngier
2020-12-28 10:49 ` [PATCH 07/17] arm64: Simplify init_el2_state to be non-VHE only Marc Zyngier
2020-12-28 10:49 ` [PATCH 08/17] arm64: Move SCTLR_EL1 initialisation to EL-agnostic code Marc Zyngier
2020-12-28 10:49 ` [PATCH 09/17] arm64: cpufeature: Add global feature override facility Marc Zyngier
2020-12-28 10:49 ` [PATCH 10/17] arm64: Extract early FDT mapping from kaslr_early_init() Marc Zyngier
2020-12-28 10:49 ` [PATCH 11/17] arm64: cpufeature: Add an early command-line cpufeature override facility Marc Zyngier
2020-12-28 10:49 ` [PATCH 12/17] arm64: Allow ID_AA64MMFR1_EL1.VH to be overridden from the command line Marc Zyngier
2020-12-28 10:49 ` [PATCH 13/17] arm64: Honor VHE being disabled from the command-line Marc Zyngier
2020-12-28 10:49 ` [PATCH 14/17] arm64: Add an aliasing facility for the idreg override Marc Zyngier
2020-12-28 10:49 ` [PATCH 15/17] arm64: Make kvm-arm.mode={nvhe, protected} an alias of id_aa64mmfr1.vh=0 Marc Zyngier
2020-12-28 10:49 ` [PATCH 16/17] KVM: arm64: Document HVC_VHE_RESTART stub hypercall Marc Zyngier
2020-12-28 10:49 ` [PATCH 17/17] arm64: Move "nokaslr" over to the early cpufeature infrastructure Marc Zyngier
2020-12-29 19:27 ` [PATCH 00/17] arm64: Early CPU feature override, and an application to VHE Marc Zyngier
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20201228104958.1848833-5-maz@kernel.org \
--to=maz@kernel.org \
--cc=ardb@kernel.org \
--cc=catalin.marinas@arm.com \
--cc=kernel-team@android.com \
--cc=kvmarm@lists.cs.columbia.edu \
--cc=linux-arm-kernel@lists.infradead.org \
--cc=will@kernel.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).